File:Gaussian beam with german description.svg

From Wikimedia Commons, the free media repository

File
File history
File links

Gaussian_beam_with_german_description.svg‎ (SVG file, nominally 1,200 × 600 pixels, file size: 332 KB)

Description	Gaussian beam with German description English: This is a schematical drawing of a Gaussian beam with German description and fundamental dimensions. Usually, laser beams can be described as Gaussian beams. Deutsch: Die Zeichnung stellt schematisch einen Gaußstrahl dar, angegeben sind grundlegende Abmessungen. Üblicherweise werden Laserstrahlen als Gaußstrahlen behandelt. Software Gnuplot, script is given below. Unfortunately, the script creates several items twice, so I had to remove them with Inkscape. Inkscape
Date	March 2008(2008-03)
Source	Own work
Author	א (Aleph)
Permission (Reusing this image)	see below

[edit] Licensing

This file is licensed under the Creative Commons Attribution ShareAlike 2.5 License. In short: you are free to share and make derivative works of the file under the conditions that you appropriately attribute it, and that you distribute it only under a license identical to this one. Official license

If you use this image, you have to credit this: Image by א (Aleph), http://commons.wikimedia.org

Wenn Sie dieses Bild verwenden, müssen Sie folgendes angeben: Bild von א (Aleph), http://commons.wikimedia.org

[edit] Gnuplot Script

# #############################################################
#
# This file was created by א and may 
# only be used under the terms of the 
# Creative-Commons-License CC-BY-SA-2.5 
# with apropriate attribution. 
#
# You MUST credit this: א (Aleph), http://commons.wikimedia.org
#
# #############################################################
# Gnuplot code as follows:
reset
set terminal svg enhanced size 1200 600 fsize 36 fname "Arial"
set output "gaussian_beam_german.svg"
set multiplot
# Variables used for gaussian beam
w0 = 2.0
z0 = 4.0
# Configure coordinate system
# set xzeroaxis linetype rgb "black"
# set yzeroaxis linetype rgb "black"
unset border
unset tics
set xtics axis mirror ("−z_0" -z0, "+z_0" z0) offset 0,0.75 scale 0.5
set xrange [-20:20]
set yrange [-12:10]
set label "z" at 18,-0.5
set label "r" at 0.5,8.5
# Arrows along the axes
set style arrow 2 filled size 1,10
set arrow arrowstyle 2 from -20,0 to 20,0
set arrow arrowstyle 2 from 0,-10 to 0,10
# Function for gaussian beam
w(z) = w0*sqrt(1+(z/z0)**2)
# Function for asymptotes
a(z) = w0/z0 * z
# Arrow for w0
set style arrow 1 heads filled size 0.5,10 front
set arrow arrowstyle 1 from 0,0 to 0,w0
set label "w_0" at 0.25,1.25
# Arrow for w(z)
z1 = 12
set arrow arrowstyle 1 from -z1,0 to -z1,w(z1)
set label "w(z)" at -z1+0.25,0.5*w(z1)
# Lines at the end of b
set style arrow 3 nohead lt rgb "grey"
set arrow arrowstyle 3 from z0,0 to z0,4
set arrow arrowstyle 3 from -z0,0 to -z0,4
# Arrow for b
set arrow arrowstyle 1 from -z0,w(z0)+1 to z0,w(z0)+1
set label "b" at -1,w(z0)+2.
# Arrow for w(z0)
set arrow arrowstyle 1 from -z0,0 to -z0,w(z0)
set label "√2·w_0" at -z0-4,0.5*w(z0)
k=2.5 #Variable needed for wavefronts
R(k) = k*(1+(z0/k)**2) # Radius of wavefronts
zM(k) = k - R(k) # Centre of wavefronts
# This is where the Wavefronts touch the border of the beam:
zQ(k) = zM(k)/(1.0 + (w0/z0)**2) + sqrt((zM(k)/(1.0+(w0/z0)**2))**2 - (w0**2+zM(k)**2-R(k)**2)/(1.0+(w0/z0)**2))
W(z) = z >= zQ(k) ? sqrt(R(k)**2-(z-zM(k))**2) : 1/0 # Wavefront ist plotted for k >= zQ only.
set dummy z
set key at 18.0,-10.0
# Plot wavefronts with many samples
set samples 100000
plot W(z) lt rgb "black" title "Wellenfronten", -W(z) lt rgb "black" notitle
k = k+2.5
plot W(z) lt rgb "black" notitle, -W(z) lt rgb "black" notitle
k = k+2.5
plot W(z) lt rgb "black" notitle, -W(z) lt rgb "black" notitle
k = k+2.5
plot W(z) lt rgb "black" notitle, -W(z) lt rgb "black" notitle
k = k+2.5
plot W(z) lt rgb "black" notitle, -W(z) lt rgb "black" notitle
k = k+2.5
plot W(z) lt rgb "black" notitle, -W(z) lt rgb "black" notitle
k = k+2.5
plot W(z) lt rgb "black" notitle, -W(z) lt rgb "black" notitle
set samples 1000
# Plot grey lines
plot w0 linetype rgb "grey" linewidth 1 notitle, -w0 linetype rgb "grey" linewidth 1 notitle, a(z) linetype rgb "grey" linewidth 1 notitle, -a(z) linetype rgb "grey" linewidth 1 notitle
# Plot borders of the beam
set key at 18.0,-12.0
plot w(z) lt rgb "red" linewidth 3 title "Begrenzung des Gaußstrahls", -w(z) linetype rgb "red" linewidth 3 notitle
# Angle Θ
set label "Θ" at -3.25,0.75
set polar
theta = atan(w0/z0)
set trange [-pi-theta:-pi+theta]
plot 2 lt rgb "black" notitle
# Undo everything
reset

File history

Click on a date/time to view the file as it appeared at that time.

	Date/Time	Thumbnail	Dimensions	User	Comment
current	15:43, 2 April 2008		1,200×600 (332 KB)	א (talk \| contribs)
	15:39, 2 April 2008		1,200×600 (331 KB)	א (talk \| contribs)
	19:53, 31 March 2008		1,200×600 (345 KB)	א (talk \| contribs)
	18:07, 31 March 2008		1,200×600 (410 KB)	א (talk \| contribs)	({{Information \|Description='''Gaussian beam with German description''' {{en\|This is a schematical drawing of a Gaussian beam with German description and fundamental dimensions. Usually, laser beams can be described as Gaussian beams.}} {{de\|Die Zeichnung)