File:MATLABUChart.png

#!/usr/bin/perl -w

#
# randomly generate process observations that simulate a
# Poisson-distributed process in the state of statistical control
# (c_setup.csv) and simulate the same process experiencing a drift of
# magnitude $drift starting two hours into the $shift shift
# (c_monitoring.csv)
#

use strict;
use Math::Random;

my %shiftSchedule = (
    "first" =>  { "start" =>  6.00, "end" => 14.00 },
    "second" => { "start" => 14.00, "end" => 22.00 },
    "third" =>  { "start" => 22.00, "end" =>  6.00 }
);
my $shift = "third";         # shift to monitor
my $inspectionRate = 1 / 2;  # every 1/2 hour
my $drift = 1.5;             # sigma drift to simulate
my $m = 25;                  # samples in control chart setup
my $target = 0.10;           # fraction nonconforming target

my $c = $target;
my $n = 48;                  # observations per sample
my $hour;
my $i;
my $minute;
my @observations;
my $observation;
my $setupM = $m;

#
# simulate control chart setup
#
open(SETUPCSV, ">c_setup.csv") || die "! can't open \"c_setup.csv\" ($!)\n";
for ($i = 1; $i <= $m; $i++) {
    @observations = Math::Random::random_poisson($n, $c);
    $observation = 0;
    map { $observation += $_ } @observations;
    print SETUPCSV $observation . "\r\n";
}
close(SETUPCSV);

#
# simulate control chart monitoring
#
open(MONITORINGCSV, ">c_monitoring.csv") || die "! can't open \"c_monitoring.csv\" ($!)\n";
$m = $shiftSchedule{$shift}{"end"} - $shiftSchedule{$shift}{"start"};
if ($m < 0) {
    $m += 24;
}
$m /= $inspectionRate;
for ($i = 1; $i <= $m; $i++) {
    $hour = int($i * $inspectionRate + $shiftSchedule{$shift}{"start"});
    if ($hour >= 24) {
        $hour -= 24;
    }
    $minute = ($i & 0x1) ? (60 * $inspectionRate) : 0;
    if ($i >= (0.25 * $m)) {
        if ($i < (0.75 * $m)) {
            $c = $target + ($drift * $target / (0.5 * $m)) * ($i - (0.25 * $m));
        } else {
            $c = $target + $drift * $target;
        }
    }
    @observations = Math::Random::random_poisson($n, $c);
    $observation = 0;
    map { $observation += $_ } @observations;
    printf MONITORINGCSV "'%d:%02d',%d\r\n", $hour, $minute, $observation;
}
close(MONITORINGCSV);