File:Blue Trefoil Knot.png

From Wikimedia Commons, the free media repository
Jump to navigation Jump to search

Original file(1,690 × 1,800 pixels, file size: 583 KB, MIME type: image/png)

Povray logo sphere.png
This image was created with POV-Ray.

Summary[edit]

Description
English: A trefoil knot.
Date
Source Own work
Author Jim.belk

Licensing[edit]

Public domain I, the copyright holder of this work, release this work into the public domain. This applies worldwide.
In some countries this may not be legally possible; if so:
I grant anyone the right to use this work for any purpose, without any conditions, unless such conditions are required by law.

Source[edit]

This image was created using POV-Ray for Windows, version 3.6. The image was rendered to an 1800 x 1800 square, using 0.3 anti-aliasing.

#include "colors.inc"
     
/* Makes a trefoil knot using a hypotrochoid */
    
background { color White }

global_settings { assumed_gamma 1.0}

camera
  {
  location <0, 0, -25>
  right <1,0,0> up <0,1,0>
  look_at  <0, 0, 0>
  angle 5
  }


light_source
  {
  <0, 20, -50>
  color White
  area_light <5, 0, 0>, <0, 5, 0>, 10, 10  /* very slow, decrease 10 to 2 for experiments */
  adaptive 3
  }
  
#declare r_tube = 0.1;
#declare num_steps = 36;
#declare step_size = 1/num_steps;
              

sphere_sweep
  {
  cubic_spline num_steps+3,
  #declare N = -1;
  #while(N <= num_steps + 1)
    #declare theta = 2 * pi * N * step_size;
    <0.3*( 2*sin(2*theta)-sin(theta) ), 0.3*( 2*cos(2*theta)+cos(theta) ), 0.3*sin(3*theta)>, r_tube
    /* uses a hypotrochoid */
    #declare N = N + 1;
  #end
  pigment { color rgb <0,0.25,1> }
  finish          
    {
    ambient 0.15
    diffuse 0.85
    brilliance 2
    phong 0.25
    phong_size 5
    }
  }


plane
  {
  <0,0,-1>, -0.4
  pigment { color White }
  finish
    {
    ambient 0.35
    diffuse 0.65
    }
  }

File history

Click on a date/time to view the file as it appeared at that time.

Date/TimeThumbnailDimensionsUserComment
current15:45, 15 May 2015Thumbnail for version as of 15:45, 15 May 20151,690 × 1,800 (583 KB)RokerHRO (talk | contribs)optipng -o7 -i0 → 5.71% decrease
00:13, 6 February 2011Thumbnail for version as of 00:13, 6 February 20111,690 × 1,800 (619 KB)Beao (talk | contribs)Transparent.
23:16, 22 March 2010Thumbnail for version as of 23:16, 22 March 20101,690 × 1,800 (530 KB)AnonMoos (talk | contribs)cropping left and right margins, increasing PNG compression
18:43, 21 March 2010Thumbnail for version as of 18:43, 21 March 20101,800 × 1,800 (993 KB)Jim.belk (talk | contribs){{Information |Description={{en|1=A trefoil knot.}} |Source={{own}} |Author=Jim.belk |Date=2010-03-21 |Permission= |other_versions= }} Category:Trefoil knots
  • You cannot overwrite this file.

The following page uses this file:

File usage on other wikis

The following other wikis use this file:

Metadata