File:Borromean Rings Illusion.png

From Wikimedia Commons, the free media repository
Jump to navigation Jump to search
Original file(1,726 × 1,713 pixels, file size: 603 KB, MIME type: image/png)
Povray logo sphere.png
This image was created with POV-Ray.

Summary[edit]

Description
English: The Borromean rings. This picture is an optical illusion: three flat circles cannot actually be connected in this way.
Date
Source Own work
Author Jim.belk
Converted to SVG.svg
This math image could be recreated using vector graphics as an SVG file. This has several advantages; see Commons:Media for cleanup for more information. If an SVG form of this image is available, please upload it and afterwards replace this template with {{vector version available|new image name}}. It is recommended to name the SVG file "Borromean Rings Illusion.svg" - then the template Vector version available (or Vva) does not need the new image name parameter.

Licensing[edit]

Public domain I, the copyright holder of this work, release this work into the public domain. This applies worldwide.
In some countries this may not be legally possible; if so:
I grant anyone the right to use this work for any purpose, without any conditions, unless such conditions are required by law.

Source[edit]

This image was created using POV-Ray for Windows, version 3.6. The image was rendered to an 1800 x 1800 square, using 0.3 anti-aliasing, and then cropped and compressed using pngcrush.

#include "colors.inc"

background { color White }

global_settings { assumed_gamma 1.0}

camera
  {
  location <0, 0, -250000>
  right <1,0,0> up <0,1,0>
  look_at  <0, 0, 0>
  angle 5/10000
  }

light_source
  {
  <0, 200000, -500000>
  color White
  area_light <50000, 0, 0>, <0, 50000, 0>, 10, 10  /* very slow, decrease 10 to 2 for experiments */
  adaptive 3
  }

#declare r_tube = 0.07;  // thickness (radius) of tube

#declare sep = 0.2; // apparent height seperation between crossing rings

#declare shiny = finish {
    ambient 0.15
    diffuse 0.85
    brilliance 2
    phong 0.25
    phong_size 7.5
    }

#declare GREEN_TORUS = torus
  {
  0.6, r_tube              // major and minor radius
  rotate -90*x      // so we can see it from the top
  translate 0.3*<cos(pi/6),sin(pi/6),0>+<0,.1,0>
  pigment { color rgb <0,0.75,0> }
  finish {shiny}
  }

#declare RED_TORUS = torus
  {
  0.6, r_tube              // major and minor radius
  rotate -90*x      // so we can see it from the top
  translate 0.3*<-cos(pi/6),sin(pi/6),0> +<0,.1,0>
  pigment { color rgb <1,0,0> }
  finish {shiny}
  }

#declare BLUE_TORUS = torus
  {
  0.6, r_tube              // major and minor radius
  rotate -90*x      // so we can see it from the top
  translate 0.3*<0,-1,0>+<0,.1,0>
  pigment { color rgb <0,0.25,1> }
  finish {shiny}
  }
  
object { RED_TORUS }
object { GREEN_TORUS }
object { BLUE_TORUS }  

intersection
  {
  object { RED_TORUS translate <0,0,-100-sep> }
  cylinder { <0,-0.3,0>, <0,-0.3,-105>, 0.25 }
  }
intersection
  {
  object { GREEN_TORUS translate <0,0,-100> }
  cylinder { <0,-0.3,0>, <0,-0.3,-105>, 0.25 }
  }

intersection
  {
  object { BLUE_TORUS translate <0,0,-100-sep> }
  cylinder { <-0.58,-0.24,-95>, <-0.58,-0.24,-105>, 0.25 }
  }
intersection
  {
  object { RED_TORUS translate <0,0,-100> }
  cylinder { <-0.58,-0.24,-95>, <-0.58,-0.24,-105>, 0.25 }
  }

intersection
  {
  object { GREEN_TORUS translate <0,0,-100-sep> }
  cylinder { <0.58,-0.24,-95>, <0.58,-0.24,-105>, 0.25 }
  }
intersection
  {
  object { BLUE_TORUS translate <0,0,-100> }
  cylinder { <0.58,-0.24,-95>, <0.58,-0.24,-105>, 0.25 }
  }

intersection
  {
  object { GREEN_TORUS translate <0,0,-100-sep> }
  cylinder { <-0.29,0.35,-95>, <-0.29,0.35,-105>, 0.25 }
  }
intersection
  {
  object { BLUE_TORUS translate <0,0,-100> }
  cylinder { <-0.29,0.35,-95>, <-0.29,0.35,-105>, 0.25 }
  }

intersection
  {
  object { BLUE_TORUS translate <0,0,-100-sep> }
  cylinder { <0.29,0.35,-95>, <0.29,0.35,-105>, 0.25 }
  }
intersection
  {
  object { RED_TORUS translate <0,0,-100> }
  cylinder { <0.29,0.35,-95>, <0.29,0.35,-105>, 0.25 }
  }

intersection
  {
  object { RED_TORUS translate <0,0,-100-sep> }
  cylinder { <0,0.85,-95>, <0,0.85,-105>, 0.25 }
  }
intersection
  {
  object { GREEN_TORUS translate <0,0,-100> }
  cylinder { <0,0.85,-95>, <0,0.85,-105>, 0.25 }
  }

plane
  {
  <0,0,-1>, -0.33
  pigment { color White }
  finish
    {
    ambient 0.35
    diffuse 0.65
    }
  }

File history

Click on a date/time to view the file as it appeared at that time.

Date/TimeThumbnailDimensionsUserComment
current14:13, 27 March 2010Thumbnail for version as of 14:13, 27 March 20101,726 × 1,713 (603 KB)AnonMoos (talk | contribs)Jim.belk, hate to be hypercritical, but it needs a little bit more cropping...
16:44, 26 March 2010Thumbnail for version as of 16:44, 26 March 20101,800 × 1,750 (607 KB)Jim.belk (talk | contribs){{Information |Description={{en|1=The Borromean rings. This picture is an optical illusion: three flat circles cannot actually be connected in this way.}} |Source={{own}} |Author=Jim.belk |Date=2010-03-26 |Permission= |other_versions= }
  • You cannot overwrite this file.

There are no pages that link to this file.

File usage on other wikis