File:Qm timedomain debroglie wavelength.gif

Summary[edit]

Mathematica 11.0 code[edit]

L = 100; (*System size*)
dx = 0.1; (*Space step*)
dt = 0.01; (*time step*)
k0 = 0; (*Momentum of the incident packet*)
V1 = Table[30 - (30 x)/L, {x, 0, L, dx}]; (*Potential*)
dim = Dimensions[V1][[1]]
(*For a undergraduate level explanation of why this works, see physik.uni-graz.at/~pep/Theses/BachelorThesis_Wachter_2017.pdf *)

\[Alpha] = (I dt)/(2 dx^2);
\[Xi]1 = Table[1 + (I dt)/2 (2/dx^2 + V1[[j]]), {j, 1, dim}];
\[Gamma]1 = Table[1 - (I dt)/2 (2/dx^2 + V1[[j]]), {j, 1, dim}];
U1 = SparseArray[{Band[{1, 1}] -> \[Xi]1, Band[{2, 1}] -> -\[Alpha], Band[{1, 2}] -> -\[Alpha]}, {dim, dim}];
U2 = SparseArray[{Band[{1, 1}] -> \[Gamma]1, Band[{2, 1}] -> \[Alpha], Band[{1, 2}] -> \[Alpha]}, {dim, dim}];
\[Psi]0 = Table[E^(-((x - L/10)^2/(2 2^2))) E^(I k0 x), {x, 0, L, dx}]; (*Initial condition*)
nsteps = 1400; (*Number of time steps*)
U = Inverse[U1].U2; (*Evolution operator*)
evo1 = NestList[Dot[U, #] &, \[Psi]0, nsteps]; (*Apply the evolution operator repeatedly to obtain the soltion at each time step*)
p1 = Table[
    ListPlot[{Re[evo1[[j]] ], Abs[evo1[[j]]]}, Joined -> True, PlotRange -> {-1.1, 1.1}, Axes -> False, PlotStyle -> {Directive[Red, Thick], Directive[Black, Thick]}, PlotLegends -> Placed[{"Re[\[Psi]]", "|\[Psi]|"}, Top] ]
   , {j, 1, nsteps, 1}];
ListAnimate[p1]

Licensing[edit]

I, the copyright holder of this work, hereby publish it under the following license:

This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication.

The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission. http://creativecommons.org/publicdomain/zero/1.0/deed.enCC0Creative Commons Zero, Public Domain Dedicationfalsefalse

This file, which was originally posted to https://twitter.com/j_bertolotti/status/1108320623120601093, was reviewed on 21 March 2019 by reviewer Ronhjones, who confirmed that it was available there under the stated license on that date.