File:Raytraced ball and stick model of an icosahedron.png

#declare SteelBall = sphere{
	0 , 0.2
	texture{
		pigment{color rgb <224/255, 223/255, 219/255>}
		finish{
			reflection 0.7
			diffuse 0.5
			specular 1
			roughness 0.005
			metallic
		}
	}
	photons{
		target
		reflection on
		refraction on
	}
}

#macro Rod(End1, End2, Col)
cylinder{
	End1, End2, 0.1
	texture{
		pigment{Col}
	}
}
#end

#include "colors.inc"
#include "vert_edge.inc"

#declare phi = (1+sqrt(5))/2;
 
camera{
	location -15*z
	look_at 0
	angle 25
}

light_source{
	<-5,5,-5>
	White
	area_light
	0.3*y, 0.3*z, 15,15
	adaptive 2
	photons{
		reflection on
		refraction on
	}
}

light_source{
	<5,5,-5>
	White
	area_light
	0.3*y, 0.3*z, 15,15
	adaptive 2
	photons{
		reflection on
		refraction on
	}
}

light_source{
	0
	0.4*White
	photons{
		reflection on
		refraction on
	}
}

#macro EdgeGroup(One, Zero, Phi, Col) //One, Zero, and Phi should all be unit vectors
	Rod(One + phi*Phi, -One + phi*Phi, Col)
	Rod(One + phi*Phi, phi*Zero + Phi, Col)
	Rod(-One + phi*Phi, phi*Zero + Phi, Col)
	Rod(One + phi*Phi, -phi*Zero + Phi, Col)
	Rod(-One + phi*Phi, -phi*Zero + Phi, Col)
#end

union{
	//3 groups each of 4 vertices, the vertices of a rectangle
	object{SteelBall translate <1,0,phi>}
	object{SteelBall translate <-1,0,phi>}
	object{SteelBall translate <1,0,-phi>}
	object{SteelBall translate <-1,0,-phi>}
	
	object{SteelBall translate <0,phi,1>}
	object{SteelBall translate <0,phi,-1>}
	object{SteelBall translate <0,-phi,1>}
	object{SteelBall translate <0,-phi,-1>}
	
	object{SteelBall translate <phi,1,0>}
	object{SteelBall translate <phi,-1,0>}
	object{SteelBall translate <-phi,1,0>}
	object{SteelBall translate <-phi,-1,0>}
	
	//6 groups each of 5 edges. A short edge of a rectangle, and the edges of the two triangular faces it is a part of.
	EdgeGroup(x,y,z, Green)
	EdgeGroup(x,y,-z, Red)
	EdgeGroup(y,z,x, Blue)
	EdgeGroup(y,z,-x, Yellow)
	EdgeGroup(z,x,y, Orange)
	EdgeGroup(z,x,-y, Med_Purple)
	rotate <15,15,15>
}

global_settings{
	max_trace_level 20
	photons{count 100000}
	radiosity{recursion_limit 10}
}