File:Relativistic field of a charge.gif

From Wikimedia Commons, the free media repository
Jump to navigation Jump to search

Relativistic_field_of_a_charge.gif ‎(768 × 299 pixels, file size: 2.51 MB, MIME type: image/gif, looped, 90 frames, 9.0 s)

Captions

Captions

Electric (E), magnetic (B) field, and Poynting vector (S) generated by a charge moving at a fraction of the speed of light.

Summary[edit]

Description
English: The electric field generated by a point charge at rest points radially outward, but if the charge is moving at a sizeable fraction of c the field is compressed along the axis of movement and a magnetic field appears around the charge.
Date
Source https://twitter.com/j_bertolotti/status/1276105762876600320
Author Jacopo Bertolotti
Permission
(Reusing this file)		 https://twitter.com/j_bertolotti/status/1030470604418428929

Mathematica 12.0 code[edit]

\[Gamma] = 1/Sqrt[1 - v^2/c^2];
\[Phi] = 1/(4 \[Pi] \[Epsilon]0) (\[Gamma] q)/
   Sqrt[\[Gamma]^2 (x - v t)^2 + y^2 + z^2];
A = {v/c^2 \[Phi], 0, 0}
el = FullSimplify[-Grad[\[Phi], {x, y, z}] - D[A, t]];
b = FullSimplify[Curl[A, {x, y, z}]];
s = FullSimplify@Cross[el, b];
stopstep[t_] := t (2 - t);
p0 = Table[
   Show[
    GraphicsGrid[{
      {
       Show[
        SliceVectorPlot3D[
         el /. {\[Epsilon]0 -> 1, c -> 1, t -> 0, q -> 1, v -> stopstep[vel]}, "CenterSphere", {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, VectorStyle -> {Thick, Blue}, PlotStyle -> {Opacity[0.05]}, Lighting -> "Neutral", Boxed -> False, Axes -> False, PlotLabel -> "\!\(\*OverscriptBox[\(E\), \(\[Rule]\)]\)", LabelStyle -> {Black, Bold, FontSize -> 16}],
        Graphics3D[{Gray, Sphere[{0, 0, 0}, 0.2], Thickness[0.015], Arrowheads[0.06], Arrow[{{0, 0, 0}, {0.8 stopstep[vel], 0, 0}}] }] ]
       ,
       Show[
        SliceVectorPlot3D[
         b /. {\[Epsilon]0 -> 1, c -> 1, t -> 0, q -> 1, v -> stopstep[vel]}, "CenterSphere", {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, VectorStyle -> {Thick, Red}, PlotStyle -> {Opacity[0.05]}, Lighting -> "Neutral", Boxed -> False, Axes -> False, PlotLabel -> "\!\(\*OverscriptBox[\(B\), \(\[Rule]\)]\)", LabelStyle -> {Black, Bold, FontSize -> 16}],
        Graphics3D[{Gray, Sphere[{0, 0, 0}, 0.2], Thickness[0.015], Arrowheads[0.06], Arrow[{{0, 0, 0}, {0.8 stopstep[vel], 0, 0}}] }] ]
       ,
       Show[
        SliceVectorPlot3D[
         s /. {\[Epsilon]0 -> 1, c -> 1, t -> 0, q -> 1, v -> stopstep[vel]}, "CenterSphere", {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, VectorStyle -> {Thick, Black}, PlotStyle -> {Opacity[0.05]}, Lighting -> "Neutral", Boxed -> False, Axes -> False, PlotLabel -> "\!\(\*OverscriptBox[\(S\), \(\[Rule]\)]\)", LabelStyle -> {Black, Bold, FontSize -> 16}],
   Graphics3D[{Gray, Sphere[{0, 0, 0}, 0.2], Thickness[0.015], Arrowheads[0.06], Arrow[{{0, 0, 0}, {0.8 stopstep[vel], 0, 0}}] }] ]
       }
      }, ImageSize -> Large, Frame -> True, FrameTicks -> All]
    ,
    Graphics[{
      Text[
       Style[StringForm["v =`` c", NumberForm[stopstep[vel], {3, 2}]], Purple, Bold, FontSize -> 14], {560, -400}]
      }]
    ]
   , {vel, 0, 0.8, 0.01}];
ListAnimate[p0]

Licensing[edit]

I, the copyright holder of this work, hereby publish it under the following license:
Creative Commons CC-Zero This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication.
The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission.

File history

Click on a date/time to view the file as it appeared at that time.

Date/TimeThumbnailDimensionsUserComment
current08:36, 26 June 2020Thumbnail for version as of 08:36, 26 June 2020768 × 299 (2.51 MB)Berto (talk | contribs)Uploaded own work with UploadWizard

You cannot overwrite this file.

There are no pages that use this file.

Metadata

This file contains additional information such as Exif metadata which may have been added by the digital camera, scanner, or software program used to create or digitize it. If the file has been modified from its original state, some details such as the timestamp may not fully reflect those of the original file. The timestamp is only as accurate as the clock in the camera, and it may be completely wrong.

Retrieved from "https://commons.wikimedia.org/w/index.php?title=File:Relativistic_field_of_a_charge.gif&oldid=735636274"