File:Unambiguous quantum state discrimination - animation.gif
Jump to navigation
Jump to search
Size of this preview: 600 × 600 pixels. Other resolutions: 240 × 240 pixels | 480 × 480 pixels | 972 × 972 pixels.
Original file (972 × 972 pixels, file size: 666 KB, MIME type: image/gif, looped, 55 frames, 6.5 s)
Captions
Captions
Unambiguous quantum state discrimination for two pure states
Summary[edit]
| Description |
English: Construction of measurement operators for unambiguous quantum state discrimination for the case of two pure equiprobable states. At first, vectors and are found that are orthogonal to the (orange) initial states and , respectively. From these, (blue) non-normalized vectors and are obtained, such that the POVM measurement operators for unambiguous discrimination read for . Using these the third operator is found , which corresponds to the inconclusive result and whose eigenvector is also shown. Čeština: Konstrukce měřicích operátorů pro jednoznačné rozlišení kvantových stavů pro případ dvou čistých stavů, které mají stejnou pravděpodobnost výskytu. Nejprve jsou nalezeny vektory a , které jsou po řadě ortogonální k počátečním (oranžovým) stavům a . Z těchto jsou zkonstruovány (modré) nenormalizované vektory a tak, že POVM měřicí operátory nabývají tvaru pro . S jejich pomocí je vytvořen třetí operátor , který odpovídá neprůkaznému výsledku a jehož vlastní vektor je také vyobrazen. |
| Date | |
| Source | Own work |
| Author | JozumBjada |
Licensing[edit]
I, the copyright holder of this work, hereby publish it under the following license:
This file is licensed under the Creative Commons Attribution-Share Alike 4.0 International license.
- You are free:
- to share – to copy, distribute and transmit the work
- to remix – to adapt the work
- Under the following conditions:
- attribution – You must give appropriate credit, provide a link to the license, and indicate if changes were made. You may do so in any reasonable manner, but not in any way that suggests the licensor endorses you or your use.
- share alike – If you remix, transform, or build upon the material, you must distribute your contributions under the same or compatible license as the original.
Source code[edit]
This animation was created using Wolfram language 12.0.0 for Microsoft Windows (64-bit) (April 6, 2019). The source code follows.
(* ::Package:: *)
(* ::Title:: *)
(*Unambiguous quantum state discrimination \[LongDash] animation*)
(* ::Input::Initialization:: *)
vec[char_,idx_,ang_,italic_:True,len_:1,off_:.15]:={Arrow[{{0,0},len AngleVector[ang ]}],Text[Style[ToString[Ket[Subscript[char,idx]],TraditionalForm],If[italic,Italic,Plain],30,FontFamily->"Times",Background->White],(1+off)AngleVector[ang],{0,0},AngleVector[ang]]}
(* ::Input::Initialization:: *)
grUSD[ang1_,ang2_,stage_]:=Module[{angavg=(ang1+ang2)/2,sceneAux1,sceneAux2,scenePro,prefac,prefacI,off},
prefac=1/Sqrt[1+Abs[Cos[ang2-ang1]]];
prefacI=prefac Sqrt[2Abs[Cos[ang2-ang1]]];
off=prefac-1+0.15;
sceneAux1={RGBColor[0.4, 0.4, 1.],Disk[{0,0},.12,{ang2,ang2-\[Pi]/2}],vec["x",1,ang2-\[Pi]/2]};
sceneAux2={RGBColor[0.4, 0.4, 1.],Disk[{0,0},.14,{ang1,ang1+\[Pi]/2}],vec["x",2,ang1+\[Pi]/2]};
scenePro={Blue,Disk[{0,0},.14,{ang1,ang1+\[Pi]/2}],Disk[{0,0},.12,{ang2,ang2-\[Pi]/2}],vec["e",2,ang1+\[Pi]/2,True,prefac,off],vec["e",1,ang2-\[Pi]/2,True,prefac,off],vec["e","?",(ang1+ang2)/2,True,prefacI,Min[prefacI-1+0.2,0.15]]};
Graphics[{
{Circle[{0,0},1]},
{Thickness[0.003],Dashing[0.02],Line[{{{-1,0},{1,0}},{{0,-1},{0,1}}}]},
{Thickness[0.005],Arrowheads[0.05],
{Orange,vec["\[Psi]",1,ang1,False],vec["\[Psi]",2,ang2,False]},
Switch[stage,
1,{},
2,{sceneAux1},
3,{sceneAux1,sceneAux2},
4,{scenePro}
],
{Black,PointSize[0.02],Point[{0,0}]}
}
},ImageSize->700,PlotRange->1.25,Background->None]
];
(* ::Input::Initialization:: *)
animationUSD[t_]:=Module[{tstages=0.5,ang1=0.2,ang2=0.8,t1,t2},
{t1,t2}=tstages+(1-tstages){3,6}/7;
Which[
t<tstages,grUSD[ang1,ang2,Quotient[Rescale[t,{0,tstages},{1,5}],1]],
tstages<=t<t1,grUSD[ang1+\[Pi]/6 UnitTriangle[Rescale[t,{tstages,t1},1.2{-1,1}]],ang2,4],
t1<=t<t2,grUSD[ang1,ang2+\[Pi]/4 UnitTriangle[Rescale[t,{t1,t2},1.2{-1,1}]],4],
t2<=t,grUSD[ang1,ang2,4]
]
]
(* ::Input::Initialization:: *)
exportAnimation[fun_,name_,resolution_:100]:=Module[{init,fin,seq,durs},
SetDirectory[NotebookDirectory[]];
init=fun/@{0,.2,.3,.4};
fin=Table[fun[t],{t,.5,1,.01}];
seq=Join[init,fin];
durs=Join[Table[1.5,Length[init]],Table[0.01,Length[fin]]];
Export[name<>".gif",seq,AnimationRepetitions->Infinity,"DisplayDurations"->durs,"TransparentColor"->Automatic,"ColorMapLength"->8,"QuantizationMethod"->"MedianCut",Dithering->None,ImageResolution->resolution]
]
(* ::Input:: *)
(*Manipulate[animationUSD[t],{t,0,1},SaveDefinitions->True]*)
(* ::Input:: *)
(*exportAnimation[animationUSD,"animUSD"]*)
File history
Click on a date/time to view the file as it appeared at that time.
| Date/Time | Thumbnail | Dimensions | User | Comment | |
|---|---|---|---|---|---|
| current | 18:33, 4 December 2021 | | 972 × 972 (666 KB) | JozumBjada (talk | contribs) | Cross-wiki upload from cs.wikipedia.org |
You cannot overwrite this file.
File usage on Commons
There are no pages that use this file.
File usage on other wikis
The following other wikis use this file:
- Usage on cs.wikipedia.org
