File:Blue Trefoil Knot Animated.gif

来自Wikimedia Commons
跳转到导航 跳转到搜索

Blue_Trefoil_Knot_Animated.gif （480 × 480像素，文件大小：1.74 MB，MIME类型：image/gif、​循环、​36帧、​3.6秒）

说明

说明

添加一行文字以描述该文件所表现的内容
 
本图片使用POV-Ray创作.

摘要

[编辑]
描述
English: A trefoil knot.
日期 // 2018-12-28
来源 自己的作品
作者 Jim.belk
Animation: MichaelFrey (留言)
其他版本

许可协议

[编辑]
Public domain 我，本作品著作权人，释出本作品至公有领域。这适用于全世界。
在一些国家这可能不合法；如果是这样的话，那么：
我无条件地授予任何人以任何目的使用本作品的权利，除非这些条件是法律规定所必需的。

Source

[编辑]
#include "colors.inc"
     
/* Makes a trefoil knot using a hypotrochoid */
    
background { color White }

global_settings { assumed_gamma 1.0}

camera
  {
  location <0, 0, -25>
  right <1,0,0> up <0,1,0>
  look_at  <0, 0, 0>
  angle 5
  }

light_source
  {
  <0, 20, -50>
  color White
  area_light <5, 0, 0>, <0, 5, 0>, 10, 10  /* very slow, decrease 10 to 2 for experiments */
  adaptive 3
  }
  
#declare r_tube = 0.1;
#declare num_steps = 36;
#declare step_size = 1/num_steps;

sphere_sweep
  {
  cubic_spline num_steps+3,
  #declare N = -1;
  #while(N <= num_steps + 1)
    #declare theta = 2 * pi * N * step_size;
    <0.3*( 2*sin(2*theta)-sin(theta) ), 0.3*( 2*cos(2*theta)+cos(theta) ), 0.3*sin(3*theta)>, r_tube
    /* uses a hypotrochoid */
    #declare N = N + 1;
  #end
  pigment { color rgb <0,0.25,1> }
  finish          
    {
    ambient 0.15
    diffuse 0.85
    brilliance 2
    phong 0.25
    phong_size 5
    }
  rotate <0,360*clock,0>
  }

plane
  {
  <0,0,-1>, -2.4
  pigment { color White }
  finish
    {
    ambient 0.35
    diffuse 0.65
    }
  }

Assembly.inc

[编辑]
;http://www.f-lohmueller.de/pov_tut/animate/anim001d.htm
Antialias=Off
Antialias_Threshold=0.1
Antialias_Depth=2

Input_File_Name="knot.pov"

Initial_Frame=1
Final_Frame=36
Initial_Clock=0
Final_Clock=1

Cyclic_Animation=on
Pause_when_Done=off

build.sh

[编辑]
povray Assembly.inc +H480 +W480 +UA

convert -dispose previous -delay 10 -loop 0 *.png myimage.gif
firefox myimage.gif

文件历史

点击某个日期/时间查看对应时刻的文件。

日期/时间缩⁠略⁠图大小用户备注
当前2018年12月27日 (四) 16:432018年12月27日 (四) 16:43版本的缩略图480 × 480（1.74 MB）MichaelFrey（留言 | 贡献）{{Created with Persistence of Vision}} == {{int:filedesc}} == {{Information |Description={{en|1=A trefoil knot.}} |Source={{own}} |Author=Jim.belk |Date=2010-03-21 |Permission= |other_versions= }} == {{int:license-header}} == {{PD-self}} == Source == using 0.3 anti-aliasing. <source lang="povray"> #include "colors.inc" →Makes a trefoil knot using a hypotrochoid: background { color White } global_settings { assumed_gamma 1.0} camera { location <0, 0, -...

您不可以覆盖此文件。

以下2个页面使用本文件：

全域文件用途

元数据

此文件含有额外信息，这些信息可能是创建或数字化该文件时使用的数码相机或扫描仪所添加的。如果文件已从其原始状态修改，某些详细信息可能无法完全反映修改后的文件。

检索自“https://commons.wikimedia.org/w/index.php?title=File:Blue_Trefoil_Knot_Animated.gif&oldid=882221666”