File:Bubble memory guide patterns.png

Ich, der Urheberrechtsinhaber dieses Werkes, veröffentliche es hiermit unter der folgenden Lizenz:

Es ist erlaubt, die Datei unter den Bedingungen der GNU-Lizenz für freie Dokumentation, Version 1.2 oder einer späteren Version, veröffentlicht von der Free Software Foundation, zu kopieren, zu verbreiten und/oder zu modifizieren; es gibt keine unveränderlichen Abschnitte, keinen vorderen und keinen hinteren Umschlagtext. Der vollständige Text der Lizenz ist im Kapitel GNU-Lizenz für freie Dokumentation verfügbar.http://www.gnu.org/copyleft/fdl.htmlGFDLGNU Free Documentation Licensetruetrue

	Diese Datei ist unter der Creative-Commons-Lizenz „Namensnennung – Weitergabe unter gleichen Bedingungen 3.0 nicht portiert“ lizenziert.
	Dieses Werk darf von dir verbreitet werden – vervielfältigt, verbreitet und öffentlich zugänglich gemacht werden neu zusammengestellt werden – abgewandelt und bearbeitet werden Zu den folgenden Bedingungen: Namensnennung – Du musst angemessene Urheber- und Rechteangaben machen, einen Link zur Lizenz beifügen und angeben, ob Änderungen vorgenommen wurden. Diese Angaben dürfen in jeder angemessenen Art und Weise gemacht werden, allerdings nicht so, dass der Eindruck entsteht, der Lizenzgeber unterstütze gerade dich oder deine Nutzung besonders. Weitergabe unter gleichen Bedingungen – Wenn du das Material wiedermischst, transformierst oder darauf aufbaust, musst du deine Beiträge unter der gleichen oder einer kompatiblen Lizenz wie das Original verbreiten.
	Diese Lizenzmarkierung wurde auf Grund der GFDL-Lizenzaktualisierung hinzugefügt.http://creativecommons.org/licenses/by-sa/3.0/CC BY-SA 3.0Creative Commons Attribution-Share Alike 3.0truetrue

Du darfst es unter einer der obigen Lizenzen deiner Wahl verwenden.

Below is the code to render this image using the Persistence of Vision Raytracer:

/*
================================================
Two types of "guides" for magnetic bubble memory
------------------------------------------------
Created by Søren Peo Pedersen - see my user page
at http://da.wikipedia.org/wiki/Bruger:Peo
================================================
*/

box {<-4,-.3,.5>,<4,.3,3>     // Topmost sheet, using the T-I-T-I-T... style
  pigment {color rgb <1,1,1>}
  finish {ambient .5}
  }

box {<-4,-.3,-3>,<4,.3,-.5>   // Lower sheet, using the V-V-V-V-V... style
  pigment {color rgb <1,1,1>}
  finish {ambient .5}
  }

#declare Tguide=merge {   // Defines the shape of a T-shaped guide
  cylinder {<-.5,.3,.5>,<.5,.3,.5>,.03}
  sphere {<.5,.3,.5>,.03}
  cylinder {<.5,.3,.5>,<.5,.3,.3>,.03}
  sphere {<.5,.3,.3>,.03}
  cylinder {<.5,.3,.3>,<.1,.3,.3>,.03}  
  cylinder {<.1,.3,.3>,<.1,.3,-.5>,.03}
  sphere {<.1,.3,-.5>,.03}
  cylinder {<.1,.3,-.5>,<-.1,.3,-.5>,.03}
  sphere {<-.1,.3,-.5>,.03}
  cylinder {<-.1,.3,.3>,<-.1,.3,-.5>,.03}
  cylinder {<-.5,.3,.3>,<-.1,.3,.3>,.03}
  sphere {<-.5,.3,.3>,.03}
  cylinder {<-.5,.3,.5>,<-.5,.3,.3>,.03}  
  box {<-.5,0,.3>,<.5,.33,.5>}
  box {<-.1,0,-.5>,<.1,.33,.3>}
  pigment {color rgb .5}
  finish {ambient .5 phong 1}
  }

#declare Iguide=merge {   // Defines the shape of an I-shaped guide
  cylinder {<-.1,.3,.5>,<.1,.3,.5>,.03}
  sphere {<.1,.3,.5>,.03}
  cylinder {<.1,.3,.5>,<.1,.3,-.5>,.03}
  sphere {<.1,.3,-.5>,.03}
  cylinder {<.1,.3,-.5>,<-.1,.3,-.5>,.03}  
  sphere {<-.1,.3,-.5>,.03}
  cylinder {<-.1,.3,-.5>,<-.1,.3,.5>,.03}
  sphere {<-.1,.3,.5>,.03}
  box {<-.1,0,-.5>,<.1,.33,.5>}
  pigment {color rgb .5}
  finish {ambient .5 phong 1}
  }

#declare Vguide=merge {   // Defines the shape of a V-shaped guide
  sphere {<0,.3,0>,.03}
  cylinder {<0,.3,0>,<-1,.3,0>,.03}
  sphere {<-1,.3,0>,.03}
  cylinder {<-1,.3,0>,<-1,.3,.2>,.03}
  sphere {<-1,.3,.2>,.03}
  cylinder {<-1,.3,.2>,<-.2,.3,.2>,.03}
  sphere {<-.2,.3,.2>,.03}
  cylinder {<-.2,.3,.2>,<-.2,.3,1>,.03}
  sphere {<-.2,.3,1>,.03}
  cylinder {<-.2,.3,1>,<0,.3,1>,.03}
  sphere {<0,.3,1>,.03}
  cylinder {<0,.3,0>,<0,.3,1>,.03}
  box {<-1,.3,0>,<0,.33,.2>}
  box {<-.2,.3,.2>,<0,.33,1>}
  rotate <0,45,0>
  pigment {color rgb .5}
  finish {ambient .5 phong 1}
  }

#local Col=0;   // Loop to create rows of several stages for each guide type
#while (Col<4)
  #object {Tguide translate <1.6*Col-3.2,0,4-2.7>}  // T-shaped and
  #object {Iguide translate <1.6*Col-2.4,0,4-1.9>}  // I-shaped above,...
  #object {Vguide translate <1.6*Col-2.4,0,-2.2>}   // V-shaped ones below.
  #local Col=Col+1;
#end
#object {Tguide translate <3.2,0,4-2.7>}  // Add an extra T at the end

background {color rgb 1}  // White background color

camera {  // See the whole thing
  location <0,6.5,0>  // from straight above,
  look_at 0           // looking towards origo.
  }

light_source {      // Illumination
  <-100,150,-120>
  color rgb 1
  }