File:Euclidian and non euclidian geometry.png
Algfail (4000 × 1500 pikslit, faili suurus: 128 KB, MIME tüüp: image/png)
Pealdised
Shows three "blocks" with varying surfaces, whereon a point and som lines are "drawn" to demonstrate
- euclidian
- elliptical and
- hyperbolic geometry
To be exact, the hyperbolic surface was approximated using a chunk of the "inside" of a torus - this may not be perfectly accurate, but apparently it "looks right" in this illustration. :-)
Rendered using POV-Ray (see http://www.povray.org) and the scene description "code" below, then cropped and "numbered" using a graphics software package.
Povray source code |
---|
/*
====================================================================
Surfaces demonstrating euclidian, elliptical and hyperbolic geometry
--------------------------------------------------------------------
Created by Søren Peo Pedersen - see my user page at
http://da.wikipedia.org/wiki/Bruger:Peo
====================================================================
*/
// Macro for texture with background pattern, lines, and point "marker"
#macro SurfaceDrawing (
Point, // Position vector: Location of white point
RefLineMove, // Transformation: Where to place the yellow reference line
Lines // Object that renders the blue line(s)
)
#local BasePattern=pigment { // The underlying, dark grey checkerboard pattern
checker
color rgb 0.4
color rgb 0.6
scale <1,1000,1>
}
#local SP1 = pigment { // Checkerboard pattern with yellow "reference line" added
object {box {<-.07,-10,-10>,<.07,10,10> transform{RefLineMove}}
pigment {BasePattern}
pigment {color rgb <1,.8,.3>}
}
}
#local SP2 = pigment { // Checkerborad + yellow line with user-defined (blue) lines added
object {Lines
pigment {SP1}
pigment {color rgb <.6,.8,1>}
}
}
#local SP3 = pigment { // Checkerboard + lines with whit point "marker" added
object {
sphere { Point, .2 }
pigment {SP2}
pigment {color rgb 1}
}
}
pigment { // Definition of pigment, confined to a box slightly smaller than the "blocks"
boxed // to make the lines and point only appear on the top of the blocks
pigment_map {
[0.0000 BasePattern scale .5 translate <0,-1,0>]
[0.0001 BasePattern scale .5 translate <0,-1,0>]
[0.0001 SP3 scale .5 translate <0,-1,0>]
[1.0000 SP3 scale .5 translate <0,-1,0>]
}
scale <2,2,2> translate <0,2,0>
}
finish {ambient .7 diffuse .3}
#end // End of macro
plane {<0,1,0>,0 // White "tabletop" to receive shadows of the blocks (helps visualisation)
pigment {color rgb 1}
finish {ambient .8 diffuse .5}
}
box {<-2,0,-2>,<2,2,2> // Demonstrating euclidean geometry
texture {
SurfaceDrawing(<-.3,2,0>,
transform {rotate <0,35,0> translate <.3,0,0>},
box {<-.07,-10,-10>,<.07,10,10> rotate <0,35,0> translate <-.3,0,0>}
)
}
rotate <0,-20,0>
translate <-6,0,0>
}
intersection { // Demonstrating elliptical, or "Riemann", geometry
box {<-2,0,-2>,<2,5,2>}
sphere {<0,0,0>,2.8285}
texture {
SurfaceDrawing(<.65,2.45,1.25>,
transform {rotate <0,5,0> rotate <-45,35,0>},
box {<-.07,-10,-10>,<.07,10,10> rotate <0,-4,0> rotate <-45,35,0>}
)
}
rotate <0,-20,0>
translate <0,0,0>
}
intersection { // Demonstrating hyperbolic geometry
box {<-2,0,-2>,<2,4,2>}
torus {7.03,5 rotate <90,90,0> translate <0,4,0>}
texture {
SurfaceDrawing(<0,2.3,1>,
transform {rotate <0,90,0> rotate <-40,0,0> translate <0,4,0>},
merge {
box {<-.07,-10,-10>,<.07,10,10>
rotate <0,85,0> rotate <-30,0,0> translate <0,4,0>
}
box {<-.07,-10,-10>,<.07,10,10>
rotate <0,95,0> rotate <-30,0,0> translate <0,4,0>
}
}
)
}
rotate <0,-20,0>
translate <6,0,0>
}
camera { // Viewpoint
location <0,2100,-800>
look_at <.5,0,0>
angle .47
}
light_source {<-50,200,-100> color rgb 1.5} // Illumination
|
Luba on antud selle dokumendi kopeerimiseks, avaldamiseks ja/või muutmiseks GNU Vaba Dokumentatsiooni Litsentsi versiooni 1.2 või hilisema Vaba Tarkvara Fondi avaldatud versiooni tingimuste alusel; muutumatute osadeta, esikaane tekstideta ja tagakaane tekstideta. Sellest loast on lisatud koopia leheküljel pealkirjaga "GNU Free Documentation License".http://www.gnu.org/copyleft/fdl.htmlGFDLGNU Free Documentation Licensetruetrue |
See fail kuulub jurisdiktsiooniga sidumata Creative Commonsi litsentsi "Autorile viitamine + jagamine samadel tingimustel 3.0" alla. | ||
| ||
See litsentsimärgis lisati sellele failile GFDL-i litsentsimisuuenduse raames.http://creativecommons.org/licenses/by-sa/3.0/CC BY-SA 3.0Creative Commons Attribution-Share Alike 3.0truetrue |
Faili ajalugu
Klõpsa kuupäeva ja kellaaega, et näha sel ajahetkel kasutusel olnud failiversiooni.
Kuupäev/kellaaeg | Pisipilt | Mõõtmed | Kasutaja | Kommentaar | |
---|---|---|---|---|---|
viimane | 5. juuli 2015, kell 21:47 | 4000 × 1500 (128 KB) | Cmdrjameson (arutelu | kaastöö) | Compressed with pngout. Reduced by 66kB (34% decrease). | |
4. august 2012, kell 19:13 | 4000 × 1500 (194 KB) | Morn (arutelu | kaastöö) | redone at higher resolution | ||
7. aprill 2005, kell 23:21 | 790 × 310 (47 KB) | Peo~commonswiki (arutelu | kaastöö) | Shows three "blocks" with varying surfaces, whereon a point and som lines are "drawn" to demonstrate #euclidian #elliptical and #hyperbolic geometry Rendered using POV-Ray (see http://www.povray.org) and the scene description "code" below, then cropped an |
Sa ei saa seda faili üle kirjutada.
Faili kasutus
Seda faili kasutavad järgmised 2 lehekülge:
Globaalne failikasutus
Järgmised muud vikid kasutavad seda faili:
- Faili kasutus vikis ar.wikipedia.org
- Faili kasutus vikis arz.wikipedia.org
- Faili kasutus vikis ast.wikipedia.org
- Faili kasutus vikis az.wikipedia.org
- Faili kasutus vikis ba.wikipedia.org
- Faili kasutus vikis bg.wikipedia.org
- Faili kasutus vikis cs.wikipedia.org
- Faili kasutus vikis en.wikipedia.org
- Faili kasutus vikis eo.wikipedia.org
- Faili kasutus vikis et.wikipedia.org
- Faili kasutus vikis fa.wikipedia.org
- Faili kasutus vikis fr.wikipedia.org
- Faili kasutus vikis gl.wikipedia.org
- Faili kasutus vikis he.wikipedia.org
- Faili kasutus vikis hy.wikipedia.org
- Faili kasutus vikis id.wikipedia.org
- Faili kasutus vikis ja.wikipedia.org
- Faili kasutus vikis ka.wikipedia.org
- Faili kasutus vikis kk.wikipedia.org
- Faili kasutus vikis la.wikipedia.org
- Faili kasutus vikis nl.wikipedia.org
- Faili kasutus vikis nn.wikipedia.org
- Faili kasutus vikis no.wikipedia.org
- Faili kasutus vikis pl.wikipedia.org
- Faili kasutus vikis tg.wikipedia.org
- Faili kasutus vikis tt.wikipedia.org
- Faili kasutus vikis uk.wikipedia.org
- Faili kasutus vikis uk.wikiquote.org
- Faili kasutus vikis uz.wikipedia.org
- Faili kasutus vikis vi.wikipedia.org
- Faili kasutus vikis www.wikidata.org
Metaandmed
See fail sisaldab lisateavet, mille on tõenäoliselt lisanud digikaamera või skanner.
Kui faili on rakendustarkvaraga töödeldud, võib osa andmeid olla muudetud või täielikult eemaldatud.
Horisontaalne eraldus | 35,43 dpc |
---|---|
Vertikaalne eraldus | 35,43 dpc |
Faili muutmise kuupäev ja kellaaeg | 4. august 2012, kell 19:09 |