File:Euclidian and non euclidian geometry.png
出典:ウィキメディア・コモンズ (Wikimedia Commons)
ナビゲーションに移動
検索に移動
このプレビューのサイズ: 800 × 300 ピクセル。 その他の解像度: 320 × 120 ピクセル | 640 × 240 ピクセル | 1,024 × 384 ピクセル | 1,280 × 480 ピクセル | 4,000 × 1,500 ピクセル。
元のファイル (4,000 × 1,500 ピクセル、ファイルサイズ: 128キロバイト、MIME タイプ: image/png)
ファイル情報
構造化データ
キャプション
Shows three "blocks" with varying surfaces, whereon a point and som lines are "drawn" to demonstrate
- euclidian
- elliptical and
- hyperbolic geometry
To be exact, the hyperbolic surface was approximated using a chunk of the "inside" of a torus - this may not be perfectly accurate, but apparently it "looks right" in this illustration. :-)
Rendered using POV-Ray (see http://www.povray.org) and the scene description "code" below, then cropped and "numbered" using a graphics software package.
Povray source code |
---|
/*
====================================================================
Surfaces demonstrating euclidian, elliptical and hyperbolic geometry
--------------------------------------------------------------------
Created by Søren Peo Pedersen - see my user page at
http://da.wikipedia.org/wiki/Bruger:Peo
====================================================================
*/
// Macro for texture with background pattern, lines, and point "marker"
#macro SurfaceDrawing (
Point, // Position vector: Location of white point
RefLineMove, // Transformation: Where to place the yellow reference line
Lines // Object that renders the blue line(s)
)
#local BasePattern=pigment { // The underlying, dark grey checkerboard pattern
checker
color rgb 0.4
color rgb 0.6
scale <1,1000,1>
}
#local SP1 = pigment { // Checkerboard pattern with yellow "reference line" added
object {box {<-.07,-10,-10>,<.07,10,10> transform{RefLineMove}}
pigment {BasePattern}
pigment {color rgb <1,.8,.3>}
}
}
#local SP2 = pigment { // Checkerborad + yellow line with user-defined (blue) lines added
object {Lines
pigment {SP1}
pigment {color rgb <.6,.8,1>}
}
}
#local SP3 = pigment { // Checkerboard + lines with whit point "marker" added
object {
sphere { Point, .2 }
pigment {SP2}
pigment {color rgb 1}
}
}
pigment { // Definition of pigment, confined to a box slightly smaller than the "blocks"
boxed // to make the lines and point only appear on the top of the blocks
pigment_map {
[0.0000 BasePattern scale .5 translate <0,-1,0>]
[0.0001 BasePattern scale .5 translate <0,-1,0>]
[0.0001 SP3 scale .5 translate <0,-1,0>]
[1.0000 SP3 scale .5 translate <0,-1,0>]
}
scale <2,2,2> translate <0,2,0>
}
finish {ambient .7 diffuse .3}
#end // End of macro
plane {<0,1,0>,0 // White "tabletop" to receive shadows of the blocks (helps visualisation)
pigment {color rgb 1}
finish {ambient .8 diffuse .5}
}
box {<-2,0,-2>,<2,2,2> // Demonstrating euclidean geometry
texture {
SurfaceDrawing(<-.3,2,0>,
transform {rotate <0,35,0> translate <.3,0,0>},
box {<-.07,-10,-10>,<.07,10,10> rotate <0,35,0> translate <-.3,0,0>}
)
}
rotate <0,-20,0>
translate <-6,0,0>
}
intersection { // Demonstrating elliptical, or "Riemann", geometry
box {<-2,0,-2>,<2,5,2>}
sphere {<0,0,0>,2.8285}
texture {
SurfaceDrawing(<.65,2.45,1.25>,
transform {rotate <0,5,0> rotate <-45,35,0>},
box {<-.07,-10,-10>,<.07,10,10> rotate <0,-4,0> rotate <-45,35,0>}
)
}
rotate <0,-20,0>
translate <0,0,0>
}
intersection { // Demonstrating hyperbolic geometry
box {<-2,0,-2>,<2,4,2>}
torus {7.03,5 rotate <90,90,0> translate <0,4,0>}
texture {
SurfaceDrawing(<0,2.3,1>,
transform {rotate <0,90,0> rotate <-40,0,0> translate <0,4,0>},
merge {
box {<-.07,-10,-10>,<.07,10,10>
rotate <0,85,0> rotate <-30,0,0> translate <0,4,0>
}
box {<-.07,-10,-10>,<.07,10,10>
rotate <0,95,0> rotate <-30,0,0> translate <0,4,0>
}
}
)
}
rotate <0,-20,0>
translate <6,0,0>
}
camera { // Viewpoint
location <0,2100,-800>
look_at <.5,0,0>
angle .47
}
light_source {<-50,200,-100> color rgb 1.5} // Illumination
|
この作品の著作権者である私は、この作品を以下のライセンスで提供します。
この文書は、フリーソフトウェア財団発行のGNUフリー文書利用許諾書 (GNU Free Documentation License) 1.2またはそれ以降のバージョンの規約に基づき、複製や再配布、改変が許可されます。不可変更部分、表紙、背表紙はありません。このライセンスの複製は、GNUフリー文書利用許諾書という章に含まれています。http://www.gnu.org/copyleft/fdl.htmlGFDLGNU Free Documentation Licensetruetrue |
このファイルはクリエイティブ・コモンズ 表示-継承 3.0 非移植ライセンスのもとに利用を許諾されています。 | ||
| ||
このライセンスのテンプレートは、GFDLのライセンス・アップデートによりこのファイルに追加されたものです。http://creativecommons.org/licenses/by-sa/3.0/CC BY-SA 3.0Creative Commons Attribution-Share Alike 3.0truetrue |
あなたは上記のライセンスから、どれか一つ以上を選択できます。
ファイルの履歴
過去の版のファイルを表示するには、その版の日時をクリックしてください。
日付と時刻 | サムネイル | 寸法 | 利用者 | コメント | |
---|---|---|---|---|---|
現在の版 | 2015年7月5日 (日) 21:47 | 4,000 × 1,500 (128キロバイト) | Cmdrjameson (トーク | 投稿記録) | Compressed with pngout. Reduced by 66kB (34% decrease). | |
2012年8月4日 (土) 19:13 | 4,000 × 1,500 (194キロバイト) | Morn (トーク | 投稿記録) | redone at higher resolution | ||
2005年4月7日 (木) 23:21 | 790 × 310 (47キロバイト) | Peo~commonswiki (トーク | 投稿記録) | Shows three "blocks" with varying surfaces, whereon a point and som lines are "drawn" to demonstrate #euclidian #elliptical and #hyperbolic geometry Rendered using POV-Ray (see http://www.povray.org) and the scene description "code" below, then cropped an |
このファイルは上書きできません。
ファイルの使用状況
以下の 2 ページがこのファイルを使用しています:
グローバルなファイル使用状況
以下に挙げる他のウィキがこの画像を使っています:
- ar.wikipedia.org での使用状況
- arz.wikipedia.org での使用状況
- ast.wikipedia.org での使用状況
- az.wikipedia.org での使用状況
- ba.wikipedia.org での使用状況
- bg.wikipedia.org での使用状況
- cs.wikipedia.org での使用状況
- en.wikipedia.org での使用状況
- eo.wikipedia.org での使用状況
- et.wikipedia.org での使用状況
- fa.wikipedia.org での使用状況
- fr.wikipedia.org での使用状況
- gl.wikipedia.org での使用状況
- he.wikipedia.org での使用状況
- hy.wikipedia.org での使用状況
- id.wikipedia.org での使用状況
- ja.wikipedia.org での使用状況
- ka.wikipedia.org での使用状況
- kk.wikipedia.org での使用状況
- la.wikipedia.org での使用状況
- nl.wikipedia.org での使用状況
- nn.wikipedia.org での使用状況
- no.wikipedia.org での使用状況
- pl.wikipedia.org での使用状況
- tg.wikipedia.org での使用状況
- tt.wikipedia.org での使用状況
- uk.wikipedia.org での使用状況
- uk.wikiquote.org での使用状況
- uz.wikipedia.org での使用状況
- vi.wikipedia.org での使用状況
- www.wikidata.org での使用状況
メタデータ
このファイルには、追加情報があります (おそらく、作成やデジタル化する際に使用したデジタルカメラやスキャナーが追加したものです)。
このファイルが元の状態から変更されている場合、修正されたファイルを完全に反映していない項目がある場合があります。
水平方向の解像度 | 35.43dpc |
---|---|
垂直方向の解像度 | 35.43dpc |
ファイル変更日時 | 2012年8月4日 (土) 19:09 |