File:Ferromagnetism vs orthomagnetism.png

Jeg, dette værks ophavsretsindehaver, publicerer hermed værket under den følgende licens:

Tilladelse er givet til at kopiere, distribuere og/eller ændre dette dokument under betingelserne i GNU Free Documentation License', Version 1.2 eller enhver senere version udgivet af Free Software Foundation; uden et invariant afsnit, ingen forsidetekster, og ingen bagsidetekst. En kopi af licensen er inkluderet i afsnittet GNU Free Documentation License.http://www.gnu.org/copyleft/fdl.htmlGFDLGNU Free Documentation Licensetruetrue

	Denne fil er udgivet under Creative Commons Kreditering-Del på samme vilkår 3.0 Ikke-porteret-licensen.
	Du må frit: at dele – at kopiere, distribuere og overføre værket at remixe – at tilpasse værket Under følgende vilkår: kreditering – Du skal give passende kreditering, angive et link til licensen, og oplyse om der er foretaget ændringer. Du må gøre det på enhver fornuftig måde, men ikke på en måde der antyder at licensgiveren godkender dig eller din anvendelse. deling på samme vilkår – Hvis du bearbejder, ændrer eller bygger videre på dette værk, skal du distribuere dine bidrag under den samme eller en kompatibel licens som originalen.
	Denne licens blev tilføjet som en del af GFDL-licensopdateringen.http://creativecommons.org/licenses/by-sa/3.0/CC BY-SA 3.0Creative Commons Attribution-Share Alike 3.0truetrue

Below is the code to render this image using the Persistence of Vision Raytacer:

/*
================================================
Ferromagnetism and orthomagnetism
------------------------------------------------
Created by Søren Peo Pedersen - see my user page
at http://da.wikipedia.org/wiki/Bruger:Peo
================================================
*/

#declare MagnetFont="arialbd.ttf" // Font for the nomenclature on magnets
#declare NorthLtr="N";  // Letter to indicate north pole
#declare SouthLtr="S";  // Letter to indicate south pole

#declare ArrowHead=difference { // Head on arrows on sides of sample blocks:
  box {<0,-1,0>,<1,1,1> rotate <0,45,0> scale <4,1,1> translate <-.9,0,0>}
  plane {<-1,0,0>,.6}
  }

#declare DoubleArrow=merge {    // Define one complete double arrow
  box {<-.6,-1,-.015>,<.6,1,.015>}
  #object {ArrowHead}
  #object {ArrowHead scale <-1,1,1>}  
  }

#declare ArrowSet=merge {       // Declare a complete set of arrows
  #object {DoubleArrow translate <0,0,.3>}
  #object {DoubleArrow translate <0,0,-.3>}
  #object {DoubleArrow rotate <90,0,0>}
  }

#declare MagnetPair=union {   // One pair of a N and S magnetic pole
  // The magnet at the left-hand side of the image:
  box {<-15,-1,-1>,<-3,1,1> // A box shape
    pigment {
      object {
        text {ttf MagnetFont,NorthLtr,3,0 //... with letter for "north" on it
          scale 2 translate <-4.3,-.7,-1.5>
          }
        color rgb <1,0,0>
        color rgb .85
        }
      }
    finish {ambient .4}
    no_shadow
    no_reflection
    }
  // The magnet at the right-hand side of the image:
  box {<3,-1,-1>,<15,1,1> // A box shape
    pigment {
      object {
        text {ttf MagnetFont,SouthLtr,3,0 // ... with letter for "south" on it
          scale 2 translate <3.2,-.7,-1.5>
          }
        color rgb .85
        color rgb <1,0,0>
        }
      }
    finish {ambient .4}
    no_shadow
    no_reflection
    }
  }

#declare SampleShape=box{<-1,-.4,-.6>,<1,.4,.6>}  // Shape of samples

// Demonstration of "ordinary" ferromagnetic
// sample in the top half of the image:
#object {MagnetPair translate <0,2,0>}  // Magnets

#object {SampleShape  // Leftmost sample object
  rotate <100,15,0>   // "Turn and tumble" it
  pigment {           // Apply color gradient to
    gradient x        // indicate presence of
    color_map {       // magnetic poles
      [0 color rgb .75]
      [1 color rgb <.75,.25,.25>]      
      }
    scale 2.3
    translate <-1.15,0,0>
    }
  finish {ambient .4} // To slightly "flatten" shadows 
  translate <-1,2,0>   // Move to position
  }

#object {SampleShape    // Rightmost sample object
  rotate <-120,-30,90>  // "Turn and tumble" it
  pigment {             // Apply color gradient to
    gradient x          // indicate presence of
    color_map {         // magnetic poles
      [0 color rgb .75]
      [1 color rgb <.75,.25,.25>]      
      }
    scale 1.5
    translate <-.75,0,0>
    }
  finish {ambient .4} // To slightly "flatten" shadows 
  translate <1.5,2,0>   // Move to position
  }

// Demonstration of an orthomagnetic sample
// in the bottom half of the image:
#object {MagnetPair translate <0,-2,0>} // Magnets

#object {SampleShape  // Leftmost sample object
  rotate <100,15,0>   // "Turn and tumble" it
  pigment {
    object {  // Arrows to indicate orthomagnetism
      #object {ArrowSet rotate <100,15,0>}
      pigment {     // Apply color gradient
        gradient x  // to indicate presence
        color_map { // of magnetic poles
          [0 color rgb .75]
          [1 color rgb <.75,.25,.25>]      
          }
        scale 2.3
        translate <-1.15,0,0>
        }
      pigment {color rgb 0} // Color of arrows
      }
    }
  finish {ambient .4} // To slightly "flatten" shadows 
  translate <-1,-2,0> // Move to position
  }

#object {SampleShape    // Rightmost sample object  
  pigment {
    object {  // Arrows to indicare orthomagnetism
      #object {ArrowSet}
      pigment {color rgb .5}// No poles, so no color gradient!
      pigment {color rgb 0} // Color of arrows
      }
    }
  finish {ambient .4} // To slightly "flatten" shadows 
  rotate <-120,-30,90>
  translate <1.5,-2,0> // Move to position
  }

background {color rgb 1}  // White background

camera {  // Point of view:
    location <0,2,-8> // Seen from this location
    look_at <0,0,0>   // looking towards this location      
    }

// Illumination:
light_source {<20,10,-15> color rgb 1}
light_source {<-10,20,-10> color rgb 1}