File:Magnetic bubbles getting chased.png

 /*
================================================
Chasing bubbles around with a pair of mangnets
------------------------------------------------
Created by Soren Peo Pedersen - see my user page
at http://da.wikipedia.org/wiki/Bruger:Peo
================================================
*/

#declare MagnetFont="arialbd.ttf" // Font for the "N" and "S" nomenclature on magnets
#declare NorthLtr="N";  // Letter to indicate north pole
#declare SouthLtr="S";  // Letter to indicate south pole

#declare MagLayerUp=pigment { // Gradient with white
  gradient y                  // south pole side facing up
  color_map {
    [0.0 color rgb <1,0,0>]
    [1.0 color rgb <1,1,1>]
    }
  scale .602
  translate -.301
  }

#declare MagLayerDn=pigment { // Gradient with red north
  gradient y                  // pole side facing up
  color_map {
    [0.0 color rgb <1,1,1>]
    [1.0 color rgb <1,0,0>]
    }
  scale .602
  translate -.301
  }

#declare MagPattern=pigment { // Defines the pattern of the domain gradients
  object {  // This time around, domains are circular (made with the cross-
    merge { // section of a cylinder) in specific, non-random places: 
      cylinder {<-3.5,-1,-3>,<-3.5,1,-3>,.3}  // Three bubbles at
      cylinder {<-1,-1,-3.9>,<-1,1,-3.9>,.3}  // left, "fleeing"
      cylinder {<-2,-1,-2.7>,<-2,1,-2.7>,.3}  // leftmost magnet
      cylinder {<3,-1,-2>,<3,1,-2>,.3}  // Three bubbles at
      cylinder {<-1,-1,2>,<-1,1,2>,.3}  // right, attracted
      cylinder {<0,-1,-1>,<0,1,-1>,.3}  // to rightmost magnet
      }
    pigment {MagLayerUp}
    pigment {MagLayerDn}      
    }
  }

#macro Arrow(Length)  // Arrow of arbitrary length to "draw"
  merge {             // onto the surface of the sheet
    box {<.4,0,-.1>,<Length-1,1,.1>}
    difference {
      box {<-1,0,-1>,<0,1,0> rotate <0,45,0> scale <3,1,1>}
      plane {<1,0,0>,-1}
      translate <Length,0,0>
      }
    }
#end

box {<-4,-.3,-4>,<4,.3,4> // The orthomagnetic sheet...
  pigment {
    object {
      union { // Has a bunch of arrows associated with the domain "bubbles":
        #object {Arrow(3) rotate <0,-80,0> translate <-3.5,0,-3>}   // Arrows illustrating
        #object {Arrow(3) rotate <0,-15,0> translate <-1,0,-3.9>} // the flight of bubbles
        #object {Arrow(1.7) rotate <0,-45,0> translate <-2,0,-2.7>} // from left side
        #object {Arrow(3.5) rotate <0,-80,0> translate <3,0,-2>}   // Arrows illustrating
        #object {Arrow(4) rotate <0,-15,0> translate <-1,0,2>} // the bubbles moving
        #object {Arrow(5) rotate <0,-45,0> translate <0,0,-1>} // towards right side
        }
      pigment {MagPattern}  // Red/white domain pattern goes underneath arrows
      pigment {color rgb 0}
      }
    }
  finish {ambient .5}
  }

// Magnets to "squeeze" bubbles down in size:
box {<-4,3.5,-4>,<4,30,4> // The north pole above the sheet...
  pigment {
    object {
      text {ttf MagnetFont,NorthLtr,3,0 // ... with the nomenclature
        scale 10 translate <-3,4,-30>   // for "north" on it's side
        }

      pigment {color rgbt <1,0,0,.8>}
      pigment {color rgbt <1,1,1,.8>}
      }
    }
  finish {ambient .5}
  }

box {<-4,-79,-4>,<4,-4.5,4> // The south pole below the sheet...
  pigment {
    object {
      text {ttf MagnetFont "S",3,0      // ... with the nomenclature
        scale 10 translate <-3,-12,-30> // for "south" on it's side
        }
      pigment {color rgbt <1,1,1,.8>}
      pigment {color rgbt <1,0,0,.8>}
      }
    }
  finish {ambient .5}
  }

#declare SmallMagnet=box {<-.99,-.3,-.3>,<.99,.3,.3>  // Define one of the
  pigment {                                           // tiny magnets at the
    gradient x                                        // sides, pushing and
    color_map {                                       // pulling at the
      [0.0 color rgb <1,0,0>]                         // domains.
      [0.5 color rgb <1,0,0>]
      [0.5 color rgb <1,1,1>]
      [1.0 color rgb <1,1,1>]
      }
    scale 2
    }
  finish {ambient .5}  
  }

// Put tiny magnets at left and right, respectively:
#object {SmallMagnet rotate <0,0,-20> translate <-7,1,0> rotate <0,-45,0>}
#object {SmallMagnet rotate <0,0,20> translate <7,1,0> rotate <0,-45,0>}

background {color rgb 1}  // White background

camera {  // See the whole scene...
  location <7,5,-10>  // ... from this vantage point, ...
  look_at <-.7,0,0>   // ... looking towards this point.
  }

light_source {    // Light source some distance
  <-100,150,-120> // to the left of the motif
  color rgb 1
  }