File:MaxwellBoltzmann gases T0C.png
Wikimedia Commonsista
Siirry navigaatioon
Siirry hakuun
Tämän esikatselun koko: 600 × 600 kuvapistettä. Muut resoluutiot: 240 × 240 kuvapistettä | 480 × 480 kuvapistettä | 768 × 768 kuvapistettä | 1 024 × 1 024 kuvapistettä.
Alkuperäinen tiedosto (1 024 × 1 024 kuvapistettä, 43 KiB, MIME-tyyppi: image/png)
Tiedoston tiedot
Rakenteinen tieto
Kuvatekstit
Yhteenveto[muokkaa]
Maxwell-Boltzmann distribution for different gases at T=0°C. Multi-language suitable. Created with gnuplot 4.4; source code below :
#set term postscript enhanced eps color "Helvetica" 24
set term png truecolor enhanced font "Helvetica,36" size 1024,1024
set out "mb_T0.png"
# physics constants (in SI)
k = 1.38e-23
NA= 6.022e23
u = 0.001 / NA
T0 = 273.15
# Maxwell-Boltzmann distribution (mass in atomic units u, v in SI)
p(v,m,T) = 4. *pi * v**2. * (m*u/(2.*pi*k*T))**1.5 * exp( -m * u * v**2. / (2.*k*T))
# Formatting
set samples 10000
set key Left reverse at graph 0.9, 0.75
set yrange [0:.0022]
set xtics 1000 nomirror offset 0,0.25
set ytics nomirror 0.5e-3
set format y ""; set label 10 "10^{-3}" at -400,1.e-3
set border 3
set grid
set xlabel "v (m/s)" offset 13.5,2
set ylabel "p(v) (s/m)" offset 1, 5
set style fill transparent solid 0.4
# Plot for different gases at zero Celsius
set xrange [0:3900]
set label 11 "T = 0 °C" at graph 0.35, 0.8
plot p(x,28,T0) t "N_{2} (m=28 u)" w filledcurve x1, \
p(x,4,T0) t "He (m=4 u)" w filledcurve x1, \
p(x,2,T0) t "H_{2} (m=2 u)" w filledcurve x1
Lisenssi[muokkaa]
Minä, tämän teoksen tekijänoikeuksien haltija, julkaisen täten tämän teoksen seuraavalla lisenssillä:
Tämä teos on saatettu Creative Commons CC0 1.0 Yleismaailmallinen Public Domain -lausuman alaisuuteen. | |
Henkilö, joka on yhdistänyt CC0:n teokseen tai viitannut siihen teoksessa, on luovuttanut teoksen vapaaseen yleiseen käyttöön (public domain) luopumalla maailmanlaajuisesti ja soveltuvan lainsäädännön sallimassa enimmäislaajuudessa kaikista tekijänoikeuslainsäädännön alaisista oikeuksistaan teokseen, lähioikeudet ja kaikki tekijänoikeuteen liittyvät oikeudet mukaan lukien. Teosta voi lupaa pyytämättä kopioida, muokata, levittää ja esittää, mukaan lukien kaupallisessa tarkoituksessa.
http://creativecommons.org/publicdomain/zero/1.0/deed.enCC0Creative Commons Zero, Public Domain Dedicationfalsefalse |
Tiedoston historia
Päiväystä napsauttamalla näet, millainen tiedosto oli kyseisellä hetkellä.
Päiväys | Pienoiskuva | Koko | Käyttäjä | Kommentti | |
---|---|---|---|---|---|
nykyinen | 24. kesäkuuta 2013 kello 07.23 | 1 024 × 1 024 (43 KiB) | TDF (keskustelu | muokkaukset) | Fix: He instead of He2 | |
23. kesäkuuta 2013 kello 12.26 | 1 024 × 1 024 (44 KiB) | TDF (keskustelu | muokkaukset) | Maxwell-Boltzmann distribution for different gases at T=0°C. Multi-language suitable. Created with gnuplot 4.4; source code below: <code> #set term postscript enhanced eps color "Helvetica" 24 set term png truecolor enhanced font "Helvetica,36" size ... |
Et voi tallentaa uutta tiedostoa tämän tilalle.
Tiedoston käyttö
Tätä tiedostoa ei käytetä millään sivulla.
Tiedoston järjestelmänlaajuinen käyttö
Seuraavat muut wikit käyttävät tätä tiedostoa:
- Käyttö kohteessa de.wikipedia.org
- Käyttö kohteessa fi.wikipedia.org
- Käyttö kohteessa sk.wikipedia.org