File:Raytraced ball and stick model of a dodecahedron.png
Aus Wikimedia Commons, dem freien Medienarchiv
Zur Navigation springen
Zur Suche springen
Größe dieser Vorschau: 800 × 600 Pixel. Weitere Auflösungen: 320 × 240 Pixel | 640 × 480 Pixel | 1.024 × 768 Pixel | 1.280 × 960 Pixel | 2.560 × 1.920 Pixel | 4.000 × 3.000 Pixel.
Originaldatei (4.000 × 3.000 Pixel, Dateigröße: 1,49 MB, MIME-Typ: image/png)
Dateiinformationen
Strukturierte Daten
Bildtexte
Beschreibung[Bearbeiten]
BeschreibungRaytraced ball and stick model of a dodecahedron.png |
English: A raytraced ball and stick model of a cahedron, made with POV-Ray. |
Datum | |
Quelle | Eigenes Werk |
Urheber | Prateek Karandikar |
Source Code[Bearbeiten]
The include file vert_edge.inc:
#declare SteelBall = sphere{
0 , 0.2
texture{
pigment{color rgb <224/255, 223/255, 219/255>}
finish{
reflection 0.7
diffuse 0.5
specular 1
roughness 0.005
metallic
}
}
photons{
target
reflection on
refraction on
}
}
#macro Rod(End1, End2, Col)
cylinder{
End1, End2, 0.1
texture{
pigment{Col}
}
}
#end
The main source:
#include "colors.inc"
#include "vert_edge.inc"
#declare phi = (1+sqrt(5))/2;
camera{
location -13*z
look_at 0
angle 25
}
light_source{
<-5,5,-5>
White
area_light
0.3*y, 0.3*z, 15,15
adaptive 2
photons{
reflection on
refraction on
}
}
light_source{
<5,5,-5>
White
area_light
0.3*y, 0.3*z, 15,15
adaptive 2
photons{
reflection on
refraction on
}
}
light_source{
0
0.4*White
photons{
reflection on
refraction on
}
}
//6 groups each of 5 edges. Consider the inscribed cube, as in http://commons.wikimedia.org/wiki/File:Dodecahedron-with-inscribed-cube.svg . Each group consists of a "hut" made on one face of the cube
#macro EdgeGroup(Face, HutPar, HutPerp, Col) //Face identifies the face of the cube under consideration. HutPar is parallel to the roof of the "hut", and HutPerp is perpendicular to it. All these should be unit vectors. HutPar and HutPerp can be multiplied by -1 without affecting the output
Rod(phi*Face + (1/phi)*HutPar, phi*Face - (1/phi)*HutPar, Col) //The roof of the hut
Rod(phi*Face + (1/phi)*HutPar, Face + HutPar + HutPerp, Col)
Rod(phi*Face + (1/phi)*HutPar, Face + HutPar - HutPerp, Col)
Rod(phi*Face - (1/phi)*HutPar, Face - HutPar + HutPerp, Col)
Rod(phi*Face - (1/phi)*HutPar, Face - HutPar - HutPerp, Col)
#end
#declare Mone = array[2] {1,-1};
#declare Mphi = array[2] {phi,-phi};
#declare Mphirec = array[2] {1/phi,-1/phi};
union{
#declare i=0; #while (i<2)
#declare j=0; #while (j<2)
#declare k=0; #while (k<2)
object{SteelBall translate <Mone[i], Mone[j], Mone[k]>}
#declare k=k+1; #end
#declare j=j+1; #end
#declare i=i+1; #end
#declare i=0; #while (i<2)
#declare j=0; #while (j<2)
object{SteelBall translate <0, Mphirec[i], Mphi[j]>}
#declare j=j+1; #end
#declare i=i+1; #end
#declare i=0; #while (i<2)
#declare j=0; #while (j<2)
object{SteelBall translate <Mphirec[i], Mphi[j], 0>}
#declare j=j+1; #end
#declare i=i+1; #end
#declare i=0; #while (i<2)
#declare j=0; #while (j<2)
object{SteelBall translate <Mphi[j], 0, Mphirec[i]>}
#declare j=j+1; #end
#declare i=i+1; #end
EdgeGroup(x,z,y, Red)
EdgeGroup(-x,z,y, Blue)
EdgeGroup(z,y,x, Green)
EdgeGroup(-z,y,x, Yellow)
EdgeGroup(y,x,z, Orange)
EdgeGroup(-y,x,z, Med_Purple)
rotate <15,10,15>
}
global_settings{
max_trace_level 20
photons{count 100000}
radiosity{recursion_limit 10}
}
Lizenz[Bearbeiten]
Ich, der Urheberrechtsinhaber dieses Werkes, veröffentliche es hiermit unter der folgenden Lizenz:
Es ist erlaubt, die Datei unter den Bedingungen der GNU-Lizenz für freie Dokumentation, Version 1.2 oder einer späteren Version, veröffentlicht von der Free Software Foundation, zu kopieren, zu verbreiten und/oder zu modifizieren; es gibt keine unveränderlichen Abschnitte, keinen vorderen und keinen hinteren Umschlagtext.
Der vollständige Text der Lizenz ist im Kapitel GNU-Lizenz für freie Dokumentation verfügbar.http://www.gnu.org/copyleft/fdl.htmlGFDLGNU Free Documentation Licensetruetrue |
Diese Datei ist unter den Creative Commons-Lizenzen Namensnennung – Weitergabe unter gleichen Bedingungen 4.0 International, 3.0 nicht portiert, 2.5 Allgemein, 2.0 Allgemein und 1.0 Allgemein lizenziert.
- Dieses Werk darf von dir
- verbreitet werden – vervielfältigt, verbreitet und öffentlich zugänglich gemacht werden
- neu zusammengestellt werden – abgewandelt und bearbeitet werden
- Zu den folgenden Bedingungen:
- Namensnennung – Du musst angemessene Urheber- und Rechteangaben machen, einen Link zur Lizenz beifügen und angeben, ob Änderungen vorgenommen wurden. Diese Angaben dürfen in jeder angemessenen Art und Weise gemacht werden, allerdings nicht so, dass der Eindruck entsteht, der Lizenzgeber unterstütze gerade dich oder deine Nutzung besonders.
- Weitergabe unter gleichen Bedingungen – Wenn du das Material wiedermischst, transformierst oder darauf aufbaust, musst du deine Beiträge unter der gleichen oder einer kompatiblen Lizenz wie das Original verbreiten.
Du darfst es unter einer der obigen Lizenzen deiner Wahl verwenden.
Dateiversionen
Klicke auf einen Zeitpunkt, um diese Version zu laden.
Version vom | Vorschaubild | Maße | Benutzer | Kommentar | |
---|---|---|---|---|---|
aktuell | 13:54, 16. Dez. 2010 | 4.000 × 3.000 (1,49 MB) | Kprateek88 (Diskussion | Beiträge) | {{Information |Description={{en|1=A raytraced ball and stick model of an icosahedron, made with POV-Ray.}} |Source=Own work |Author=Prateek Karandikar |Date=2010-12-06 |Permission= |other_versions= }} |
Du kannst diese Datei nicht überschreiben.
Dateiverwendung
Die folgenden 2 Seiten verwenden diese Datei:
Globale Dateiverwendung
Die nachfolgenden anderen Wikis verwenden diese Datei:
- Verwendung auf da.wikipedia.org