File:Standard symmetric pdfs.svg
- Fichier
- Historique du fichier
- Utilisations locales du fichier
- Utilisations du fichier sur d’autres wikis
- Métadonnées
Fichier d’origine (Fichier SVG, nominalement de 400 × 300 pixels, taille : 390 kio)
Légendes
Description[modifier]
DescriptionStandard symmetric pdfs.svg |
English: Plot of several symmetric unimodal probability densities with unit variance. From highest to lowest peak:
|
|||||||
Date | ||||||||
Source | MarkSweep | |||||||
Auteur |
Vecteur : |
|||||||
Autorisation (Réutilisation de ce fichier) |
Moi, en tant que détenteur des droits d’auteur sur cette œuvre, je la publie sous la licence suivante :
|
|||||||
Autres versions |
File:Standard symmetric pdfs logscale.svg File:Standard symmetric pdfs.png File:Standard symmetric pdfs logscale.png |
|||||||
SVG information InfoField | ||||||||
Code source InfoField | Gnuplot code# Laplace double exponential distribution, kurtosis 3
laplace(x) = exp(-abs(x)*sqrt(2)) * sqrt(0.5)
# sech distribution, kurtosis 2
sech(x) = 2.0 / (exp(x) + exp(-x))
sech_pdf(x) = 0.5 * sech(0.5*pi*x)
# logistic distribution, kurtosis 1.2
slogist = sqrt(3) / pi
logist(x) = exp(-x/slogist) / slogist / (1 + exp(-x/slogist))**2
# normal distribution, kurtosis 0
n(x) = exp(-0.5*x*x) / sqrt(2*pi)
# raised cosine distribution, kurtosis -0.59376
scos = 1.0 / sqrt(1/3.0 - 2/pi**2)
cosine(x) = abs(x)>scos? 0 : (1+cos(x*pi/scos))*0.5/scos
# Wigner semicircle distribution, kurtosis -1
wigner(x) = abs(x)>2? 0 : sqrt(4-x*x)*0.5/pi
# uniform distribution, kurtosis -1.2
uniform(x) = abs(x)>sqrt(3)? 0 : 0.5/sqrt(3)
set samples 6001
set grid
set xrange [-5.4:5.4]
set xtics 1
set key right font ",8" enhanced
set terminal svg size 400,300 enhanced fname 'DejaVu Sans' fsize 10 butt solid
set output 'Standard symmetric pdfs.svg'
plot \
laplace(x) lt 1 lw 2 title "D, 3", \
sech_pdf(x) lt 8 lw 2 title "S, 2", \
logist(x) lt 2 lw 2 title "L, 1.2", \
n(x) lt 7 lw 2 title "N, 0", \
cosine(x) lt 5 lw 2 title "C, -0.59376", \
wigner(x) lt 3 lw 2 title "W, -1", \
uniform(x) lt 4 lw 2 title "U, -1.2"
|
Historique du fichier
Cliquer sur une date et heure pour voir le fichier tel qu'il était à ce moment-là.
Date et heure | Vignette | Dimensions | Utilisateur | Commentaire | |
---|---|---|---|---|---|
actuel | 26 mai 2020 à 16:15 | 400 × 300 (390 kio) | Andel (d | contributions) | small legend tweak | |
26 mai 2020 à 13:52 | 400 × 300 (390 kio) | Andel (d | contributions) | == {{int:filedesc}} == {{Information |description=|Description= {{en|1=Plot of several symmetric unimodal probability densities with unit variance. From highest to lowest peak: {{Legend|red|red, kurtosis 3, Laplace (D)ouble exponential distribution;}} {{Legend|orange|orange, kurtosis 2, hyperbolic (S)ecant distribution;}} {{Legend|green|green, kurtosis 1.2, (L)ogistic distribution;}} {{Legend|black|bla... |
Vous ne pouvez pas remplacer ce fichier.
Utilisations locales du fichier
Les 2 pages suivantes utilisent ce fichier :
Utilisations du fichier sur d’autres wikis
Les autres wikis suivants utilisent ce fichier :
- Utilisation sur ar.wikipedia.org
- Utilisation sur be.wikipedia.org
- Utilisation sur ca.wikipedia.org
- Utilisation sur en.wikipedia.org
- Utilisation sur en.wikibooks.org
- Utilisation sur eo.wikipedia.org
- Utilisation sur fr.wikipedia.org
- Utilisation sur ko.wikipedia.org
- Utilisation sur pt.wikipedia.org
- Utilisation sur ru.wikipedia.org
- Utilisation sur tr.wikipedia.org
- Utilisation sur www.wikidata.org
Métadonnées
Ce fichier contient des informations supplémentaires, probablement ajoutées par l'appareil photo numérique ou le numériseur utilisé pour le créer.
Si le fichier a été modifié depuis son état original, certains détails peuvent ne pas refléter entièrement l'image modifiée.
Titre court | Gnuplot |
---|---|
Titre de l’image | Produced by GNUPLOT 4.6 patchlevel 3 |
Largeur | 400 |
Hauteur | 300 |