File:TRY exchange rate to EUR - Turkish Currency and Debt Crisis 2018.svg
Aus Wikimedia Commons, dem freien Medienarchiv
Zur Navigation springen
Zur Suche springen
Größe der PNG-Vorschau dieser SVG-Datei: 800 × 400 Pixel. Weitere Auflösungen: 320 × 160 Pixel | 640 × 320 Pixel | 1.024 × 512 Pixel | 1.280 × 640 Pixel | 2.560 × 1.280 Pixel.
Originaldatei (SVG-Datei, Basisgröße: 800 × 400 Pixel, Dateigröße: 95 KB)
Dateiinformationen
Strukturierte Daten
Bildtexte
Beschreibung
[Bearbeiten]BeschreibungTRY exchange rate to EUR - Turkish Currency and Debt Crisis 2018.svg | TRY exchange rate to EUR - Turkish Currency and Debt Crisis 2018 |
Datum | |
Quelle | Eigenes Werk |
Urheber | Summer ... hier! |
Andere Versionen | Euro exchange rate to TRY.svg |
SVG‑Erstellung InfoField | Diese Vektorgrafik wurde mit Gnuplot erstellt. |
Quelltext InfoField | Gnuplot code#!/usr/bin/env gnuplot
# based on code of [[:User:Gorgo|Gorgo]]/[[c:File:Euro exchange rate to TRY.svg]]
# gnuplot script for plotting eurofxref-hist.csv as obtained from
# http://www.ecb.int/stats/exchange/eurofxref/html/index.en.html
# Before runnig this script, download and unzip to working directory:
# https://www.ecb.europa.eu/stats/eurofxref/eurofxref-hist.zip
infile='eurofxref-hist.csv'
outfile='TRY_exchange_rate_to_EUR_-_Turkish_Currency_and_Debt_Crisis_2018.svg'
# Start und Ende ermitteln (z.Zt. nur für Consolenausagabe)
stats infile every ::1 u (strptime("%Y-%m-%d",strcol(1))) nooutput
print ' -----Stats-(Timestamp)----'
print ' Start: ', strftime("%d. %B %Y",STATS_min)
print ' Ende: ', strftime("%d. %B %Y",STATS_max)
print ' --------------------------'
set label 'last update: ' . strftime("%Y-%m-%d",STATS_max) at graph 0.05, graph 0.15
#input
set timefmt "%Y-%m-%d"
set datafile missing 'N/A'
set datafile separator ','
#output
set key top right
set style data lines
set border 3 # Rahmen unten (Bit 1) und links (+ Bit 2)
unset grid # Gitterlinien verwenden
# Gitterlinienen per Hand setzen falls gewünscht
set style line 1 linetype rgb '#696969' linewidth 0.25 # Def. Major-grid
set style line 2 linetype rgb '#C9C9C9' linewidth 0.15 # def. Minor-grid
set grid noxtics nomxtics # Keine Gitterlinen an der 1. X-Achse
set grid x2tics
set grid ytics mytics # Gitterl. an der Y-Achse
set grid back # Gitter im Hintergrund
set grid linestyle 1, linestyle 2 # Setzen des linestyle für Major u. Minor
# die Kalenderwochen-Markierung machen wir über x2 !!!
set xdata time
set x2data time
set format x '1. %b'
set xtics ('') # leeren Str setzen damit per for-Schleife
# addiert werden kann
do for [month_tic=1:12] {
new_xtic = gprintf("2018-%02.0f-01", month_tic)
# print 'Setze xtic bei: ' . new_xtic # Ausgabe für Tests
set xtics add ( new_xtic )
}
if (GPVAL_VERSION >= 5.0) {
set xtics rotate by +15 center offset 0,-0.5
} else {
set xtics rotate by +15 center offset 0,-0.75
}
set format x2 ''
set xrange ['2018-01-01':'2019-01-01']
set x2range ['2018-01-01':'2019-01-01']
set x2tics '2018-01-01', 60 * 60 * 24 * 7
set x2tic scale 0
set xtics nomirror
unset mxtics
set xlabel '2018'
set ylabel 'EUR'
# set y2label 'TRY'
set format y '%.2f'
# set format y2 '%.0f'
set ytics 0.05
set mytics 5
set ytics nomirror
# Zebramuster
set style rect fillcolor lt -1 fillstyle solid 0.06 noborder
do for [i=1:12:2] {
marker_start=sprintf("2018-%1.2d-01",i)
marker_stop =sprintf("2018-%1.2d-01",i+1)
print 'setze grauen Marker: ' . marker_start . "-" . marker_stop
set object rectangle from marker_start,graph 0 to marker_stop, graph 1
}
## gnuplot for SVG - gnuplot 4.2 / Ubuntu 8.10
if (GPVAL_VERSION >= 5.0) {
set term svg size 800,400 font "Arial,16"
} else {
set term svg size 800,400 font "Arial,12"
}
set outp outfile
set style line 1 lt rgb 'blue' lw 1
#available currencies:
#first one is $2, second $3 and so on
#USD,JPY,BGN,CYP,CZK,DKK,EEK,GBP,HUF,LTL,LVL,MTL,PLN,ROL,RON,SEK,SIT,SKK,CHF,ISK,NOK,HRK,RUB,TRL,TRY,AUD,BRL,CAD,CNY,HKD,IDR,ILS,INR,KRW,MXN,MYR,NZD,PHP,SGD,THB,ZAR
plot \
infile \
usi 1:(1/$26) axis x1y1 tit '1 TRY in EUR' lt rgb 'blue' lw 1,\
infile \
usi 1:(1/$26) axis x1y1 notit w p lc rgb 'black' lt 1 lw 1.5 pt 7 ps 0.1 \
|
Lizenz
[Bearbeiten]Ich, der Urheber dieses Werkes, veröffentliche es unter der folgenden Lizenz:
Diese Datei wird unter der Creative-Commons-Lizenz „CC0 1.0 Verzicht auf das Copyright“ zur Verfügung gestellt. | |
Die Person, die das Werk mit diesem Dokument verbunden hat, übergibt dieses weltweit der Gemeinfreiheit, indem sie alle Urheberrechte und damit verbundenen weiteren Rechte – im Rahmen der jeweils geltenden gesetzlichen Bestimmungen – aufgibt. Das Werk kann – selbst für kommerzielle Zwecke – kopiert, modifiziert und weiterverteilt werden, ohne hierfür um Erlaubnis bitten zu müssen.
http://creativecommons.org/publicdomain/zero/1.0/deed.enCC0Creative Commons Zero, Public Domain Dedicationfalsefalse |
Dateiversionen
Klicke auf einen Zeitpunkt, um diese Version zu laden.
Du kannst diese Datei nicht überschreiben.
Dateiverwendung
Keine Seiten verwenden diese Datei.
Globale Dateiverwendung
Die nachfolgenden anderen Wikis verwenden diese Datei:
- Verwendung auf de.wikipedia.org
Metadaten
Diese Datei enthält weitere Informationen, die in der Regel von der Digitalkamera oder dem verwendeten Scanner stammen. Durch nachträgliche Bearbeitung der Originaldatei können einige Details verändert worden sein.
Kurztitel | Gnuplot |
---|---|
Bildtitel | Produced by GNUPLOT 5.0 patchlevel 5 |
Breite | 800 |
Höhe | 400 |