File:Anderson localization 1D vs number of layers.webm

c = 3 10^8; (*speed of light*)

M[n_, k_, d_] := {{Cos[n k d], I c/n Sin[n k d]}, {I n/c Sin[n k d], Cos[n k d]}}; (*transfer matrix*)

Mi[n_, k_, d_] := {{Cos[d k n], -((I c Sin[d k n])/n)}, {-((I n Sin[d k n])/c), Cos[d k n]}}; (*Inverse of a transfer matrix*)

t[m_, n0_, n2_] := (2 n0/c)/(n2/c m[[1, 1]] - (n0 n2)/c^2 m[[1, 2]] - m[[2, 1]] + n0/c m[[2, 2]]); (*transmission coefficient*)
d = 0.4 10^-6; (*layer thickness in m*)
nstep = 1500;
\[Omega]min = 405. 10^12;
\[Omega]max = 790. 10^12;
dimmax = 200; (*number of layers in the Bragg mirror*)

nlayermax = dimmax - 10;
randn = RandomReal[{1.5, 2.5}, nlayermax];
p0 = Reap[For[nlayers = 0, nlayers <= nlayermax, nlayers++,
      s = Join[Table[1., 10], Table[randn[[j]], {j, 1, nlayers}], Table[1., dimmax - nlayers - 10]];(*Reflective indices of each layer (including some space to show the pulse arrive*)
      dim = Dimensions[s][[1]];
      trasm = 
       Reap[For[\[Omega] = \[Omega]min, \[Omega] <= \[Omega]max, \[Omega] = \[Omega] + (\[Omega]max - \[Omega]min)/nstep,
           tm = Apply[Dot, Table[M[s[[j]], \[Omega]/c, d], {j, 1, dim}]];
           Sow[N[t[tm, 1, 1]] ];
           ];][[2, 1]];
      field = trasm; (*Field at the last interface*)
      sexpand = 1; (*increase spatial resolution*)
      s2 = Flatten@Table[Table[s[[j]], sexpand], {j, 1, dim}];
      freq = Table[j, {j, \[Omega]min, \[Omega]max, (\[Omega]max - \[Omega]min)/nstep}];
      fn = Transpose[{field, field/c}];
      tmp0 = fn;
      ssm = Reap[For[i = dim*sexpand, i > 0, i--,
           tmp = Table[((Mi[s2[[i]], freq/c, d/sexpand])[[All, All, j]].tmp0[[j]]), {j, 1, nstep}];
           Sow[tmp[[All, 1]]];
           tmp0 = tmp;
           ];][[2, 1]];
      Sow@Grid[{
         {ListPlot[Abs[trasm]^2, Joined -> True, 
           DataRange -> {\[Omega]min, \[Omega]max}, 
           AspectRatio -> 1/2, ImagePadding -> {{40, 10}, {5, 0}}, 
           ImageSize -> {250, UpTo[250]}, PlotStyle -> {Thick, Black},
            Axes -> False, Frame -> True, 
           FrameTicks -> {{{0, 0.5, 1}, None}, {None, None}}, 
           FrameStyle -> {Directive[Thick, Gray]}, 
           FrameLabel -> {None, "T"}, Ticks -> {None, Automatic}, 
           LabelStyle -> {Black, Bold}, PlotRange -> {0, 1.05}]
          , ""
          }, {
          
          ArrayPlot[Abs[ssm]/1.5, AspectRatio -> 1, 
           ColorFunction -> "SunsetColors", 
           ColorFunctionScaling -> False, Frame -> True, 
           FrameTicks -> {{None, None}, {Automatic, None}}, 
           DataRange -> {{\[Omega]min, \[Omega]max}, {0, 
              d*Dimensions[s][[1]]}}, 
           ImagePadding -> {{40, 10}, {35, 0}}, ImageSize -> 250, 
           FrameLabel -> {None, "\[Omega]"}, 
           LabelStyle -> {Black, Bold}]
          ,
          
          BarLegend[{"SunsetColors", {0, 1}}, 
           LegendLabel -> Placed["|E|", Right], LegendMargins -> 0, 
           Ticks -> None, LabelStyle -> Directive[Bold]]
          }
         }, Alignment -> Top]
      ];][[2, 1]];
ListAnimate[p0]

I, the copyright holder of this work, hereby publish it under the following license:

This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication.

The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission. http://creativecommons.org/publicdomain/zero/1.0/deed.enCC0Creative Commons Zero, Public Domain Dedicationfalsefalse

This file, which was originally posted to https://twitter.com/j_bertolotti/status/1267064606524149760, was reviewed on 12 June 2020 by reviewer Didym, who confirmed that it was available there under the stated license on that date.