File:Beta distribution cdf.svg
出自Wikimedia Commons
跳至導覽
跳至搜尋
![File:Beta distribution cdf.svg](https://upload.wikimedia.org/wikipedia/commons/thumb/1/11/Beta_distribution_cdf.svg/566px-Beta_distribution_cdf.svg.png?20141114185040)
此 SVG 檔案的 PNG 預覽的大小:566 × 425 像素。 其他解析度:320 × 240 像素 | 639 × 480 像素 | 1,023 × 768 像素 | 1,280 × 961 像素 | 2,560 × 1,922 像素。
原始檔案 (SVG 檔案,表面大小:566 × 425 像素,檔案大小:80 KB)
檔案資訊
結構化資料
說明
說明
添加單行說明來描述出檔案所代表的內容
摘要
[編輯]描述Beta distribution cdf.svg |
English: Cumulative distribution function for the Beta distribution. |
日期 | |
來源 | 自己的作品 |
作者 | Horas (留言) based on the work of Krishnavedala |
其他版本 | File:Beta_distribution_cdf.png |
Source Codes
[編輯]Using gnuplot |
---|
reset
reset session
out=2
outputpath= "./"
outputfilename="betacummulative"
if(out==1) {
set terminal qt size 1000,750 font ",14"
}
if(out==2) {
set terminal pdfcairo size 16cm,12cm font ",20" linewidth 2
set output outputpath.outputfilename.".pdf"
}
if(out==3) {
set terminal pngcairo size 800,600 font ",14"
set output outputpath.outputfilename.".png"
}
dbeta(x,a,b) = exp((a-1)*log(x)+(b-1)*log(1-x)-lgamma(a)-lgamma(b)+lgamma(a+b))
pbeta(x,a,b) = ibeta(a,b,x)
f(x,y,z) = pbeta(x,y,z)
set samples 500
set xrange [0:1]
set xtics 0.2
set yrange [0:1]
set ytics 0.2
#set xlabel "x"
set ylabel "CDF"
set key at .40,1
set grid xtics ytics mytics lw 1 lc rgb "#888888" dashtype 3 lt 1
set border 3 back lw 2 lc rgb "#222222"
set tics in nomirror scale 0.75
lww=2
set ls 1 lw lww lc rgb "#e41a1c"
set ls 2 lw lww lc rgb "#377eb8"
set ls 3 lw lww lc rgb "#4daf4a"
set ls 4 lw lww lc rgb "#984ea3"
set ls 5 lw lww lc rgb "#ff7f00"
plot \
f(x, 0.5,0.5) w l ls 1 title "{/Symbol a} = {/Symbol b} = 0.5", \
f(x, 5, 1) w l ls 2 title "{/Symbol a} = 5, {/Symbol b} = 1", \
f(x, 1, 3) w l ls 3 title "{/Symbol a} = 1, {/Symbol b} = 3", \
f(x, 2, 2) w l ls 4 title "{/Symbol a} = 2, {/Symbol b} = 2", \
f(x, 2, 5) w l ls 5 title "{/Symbol a} = 2, {/Symbol b} = 5"
if (out>1) {
set output
}
if (out == 1) {
pause -1
}
|
Using python with matplotlib, scipy and numpy toolboxes. |
---|
from matplotlib.pyplot import *
from numpy import linspace
from scipy.stats import beta
x = linspace(0,1,75)
fig = figure()
ax = fig.add_subplot(111)
ax.plot(x,beta.cdf(x,0.5,0.5),label=r"$\alpha=\beta=0.5$")
ax.plot(x,beta.cdf(x,5,1),label=r"$\alpha=5, \beta=1$")
ax.plot(x,beta.cdf(x,1,3),label=r"$\alpha=1, \beta=3$")
ax.plot(x,beta.cdf(x,2,2),label=r"$\alpha=2, \beta=2$")
ax.plot(x,beta.cdf(x,2,5),label=r"$\alpha=2, \beta=5$")
ax.grid(True)
ax.minorticks_on()
ax.legend(loc=9)
setp(ax.get_legend().get_texts(),fontsize='small')
ax.set_ylim(0,2.6)
ax.set_xlabel("x")
ax.set_ylabel("PDF")
fig.savefig("Beta_distribution_cdf.svg",bbox_inches="tight",\
pad_inches=.15)
|
授權條款
[編輯]Public domainPublic domainfalsefalse |
![]() |
此檔案不具有著作權,屬於公有領域,因為其所包含之内容均為公共財產且沒有明確的原始作者資訊。 |
檔案歷史
點選日期/時間以檢視該時間的檔案版本。
日期/時間 | 縮圖 | 尺寸 | 使用者 | 備註 | |
---|---|---|---|---|---|
目前 | 2014年11月14日 (五) 18:50 | ![]() | 566 × 425(80 KB) | Horas(留言 | 貢獻) | {{Information |Description=edited to fit to prob. density function plot. Better readability. |Date=2014-11-14 |Source={{own}} |Author= ~~~ |Permission= |other_versions= }} |
2011年6月4日 (六) 21:56 | ![]() | 640 × 495(65 KB) | Krishnavedala(留言 | 貢獻) | corrected the y-axis label and location of legend | |
2011年6月4日 (六) 21:54 | ![]() | 639 × 495(65 KB) | Krishnavedala(留言 | 貢獻) | corrected the range of y-axis | |
2011年6月4日 (六) 21:53 | ![]() | 639 × 489(68 KB) | Krishnavedala(留言 | 貢獻) | {{Information |Description ={{en|1=Cumulative distribution function for the Beta distribution. Created using python with matplotlib, scipy and numpy toolboxes. <syntaxhighligh |
無法覆蓋此檔案。
檔案用途
下列頁面有用到此檔案:
全域檔案使用狀況
以下其他 wiki 使用了這個檔案:
- be.wikipedia.org 的使用狀況
- ca.wikipedia.org 的使用狀況
- de.wikipedia.org 的使用狀況
- en.wikipedia.org 的使用狀況
- en.wikibooks.org 的使用狀況
- fi.wikipedia.org 的使用狀況
- he.wikipedia.org 的使用狀況
- it.wikipedia.org 的使用狀況
- ja.wikipedia.org 的使用狀況
- ko.wikipedia.org 的使用狀況
- pt.wikipedia.org 的使用狀況
- tl.wikipedia.org 的使用狀況
- tr.wikipedia.org 的使用狀況
- uk.wikipedia.org 的使用狀況
- zh.wikipedia.org 的使用狀況
詮釋資料
此檔案中包含其他資訊,這些資訊可能是由數位相機或掃描器在建立或數位化過程中所新增的。若檔案自原始狀態已被修改,一些詳細資料可能無法完整反映出已修改的檔案。
寬度 | 453pt |
---|---|
高度 | 340pt |