File:Cube Beam Splitter VS separation.gif

From Wikimedia Commons, the free media repository
Jump to navigation Jump to search

Cube_Beam_Splitter_VS_separation.gif ‎(523 × 523 pixels, file size: 4.72 MB, MIME type: image/gif, looped, 62 frames, 6.2 s)

Captions

Captions

Visualization of how a small gap between two triangular prisms allows to tune how much is transmitted and how much is reflected at ninety degrees in a cube beam splitter.

Summary

[edit]
Description
English: f you send a beam on a glass cube, part will be reflected back, but most will go straight through. If you split the cube into two triangular prisms, and separate them a tiny little bit, part of the beam will be reflected at 90°. This is due to the fact that the field reflected by the gap does extend a bit outside the glass, so it can couple with the upper prism and form a beam that keeps going straight. This coupling decreases with distance, so you can tune how much light you want to go where. Notice that in this visualization some light goes on the right too. This is the light reflected back from the left surface of the bottom prism. To avoid this you need an antireflection coating (not simulated here).
Date
Source https://twitter.com/j_bertolotti/status/1419597961684738049
Author Jacopo Bertolotti
Permission
(Reusing this file)		 https://twitter.com/j_bertolotti/status/1030470604418428929

Mathematica 12.0 code

[edit]
\[Lambda]0 = 0.5; k0 = 
 N[(2 \[Pi])/\[Lambda]0]; (*The wavelength in vacuum is set to 1, so all lengths are now in units of wavelengths*)
\[Delta] = \[Lambda]0/20; \[CapitalDelta] = 30*\[Lambda]0; (*Parameters for the grid*)
ReMapC[x_] := RGBColor[(2 x - 1) UnitStep[x - 0.5], 0, (1 - 2 x) UnitStep[0.5 - x]];
\[Sigma] = 2.5 \[Lambda]0;
d = \[Lambda]0/2; (*typical scale of the absorbing layer*)

imn = Table[
   Chop[5 (E^-((x + \[CapitalDelta]/2)/d) + E^((x - \[CapitalDelta]/2)/d) + E^-((y + \[CapitalDelta]/2)/d) + E^((y - \[CapitalDelta]/2)/d))], {x, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}, {y, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}]; (*Imaginary part of the refractive index (used to emulate absorbing boundaries)*)
dim = Dimensions[imn][[1]];
L = -1/\[Delta]^2*KirchhoffMatrix[GridGraph[{dim, dim}]]; (*Discretized Laplacian*)

uppertriangularmatrix[dim_] := ToeplitzMatrix[Join[{1}, ConstantArray[0, dim - 1]], ConstantArray[1, dim]];
lowerprism = BoxMatrix[150, dim]*Reverse@uppertriangularmatrix[dim] + 1;
upperprism = BoxMatrix[150, dim]*Reverse@Transpose@uppertriangularmatrix[dim] + 1;
sourcef[x_, y_] := E^(-(x^2/(2 \[Sigma]^2))) E^(-((y + \[CapitalDelta]/2)^2/(2 (\[Lambda]0/2)^2))) E^(I k0 y);
\[Phi]in = Table[Chop[sourcef[x, y] ], {x, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}, {y, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}];
prism[shift_] := Clip[RotateRight[upperprism, {0, 0}] + RotateRight[lowerprism, {0, shift}] - 1, {1, ren0}];
frames = Table[
  ren = prism[j];
  n = ren + I imn;
  b = -(Flatten[n]^2 - 1) k0^2 Flatten[\[Phi]in]; (*Right-hand side of the equation we want to solve*)
  M = L + DiagonalMatrix[SparseArray[Flatten[n]^2 k0^2]]; (*Operator on the left-hand side of the equation we want to solve*)
  \[Phi] = Partition[LinearSolve[M, b], dim]; (*Solve the linear system*)
  ImageAdd[
   ArrayPlot[ Transpose[(Re@\[Phi])][[(4 d)/\[Delta] ;; (-4 d)/\[Delta], (4 d)/\[Delta] ;; (-4 d)/\[Delta]]], DataReversed -> True, Frame -> False, PlotRange -> {-0.1, 0.1}, LabelStyle -> {Black, Bold}, ColorFunctionScaling -> True, ColorFunction -> ReMapC, ClippingStyle -> {Blue, Red}]
   ,
   ArrayPlot[Transpose[(ren - 1)/10] , DataReversed -> True , ColorFunctionScaling -> False, ColorFunction -> GrayLevel, Frame -> False]
   ]
  , {j, 0, 20, 1}];
ListAnimate[Join[Table[frames[[1]], 10], frames, Table[frames[[-1]], 10], Reverse[frames]] ]

Licensing

[edit]
I, the copyright holder of this work, hereby publish it under the following license:
Creative Commons CC-Zero This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication.
The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission.

File history

Click on a date/time to view the file as it appeared at that time.

Date/TimeThumbnailDimensionsUserComment
current08:50, 27 July 2021Thumbnail for version as of 08:50, 27 July 2021523 × 523 (4.72 MB)Berto (talk | contribs)Uploaded own work with UploadWizard

You cannot overwrite this file.

There are no pages that use this file.

Metadata

This file contains additional information such as Exif metadata which may have been added by the digital camera, scanner, or software program used to create or digitize it. If the file has been modified from its original state, some details such as the timestamp may not fully reflect those of the original file. The timestamp is only as accurate as the clock in the camera, and it may be completely wrong.

Retrieved from "https://commons.wikimedia.org/w/index.php?title=File:Cube_Beam_Splitter_VS_separation.gif&oldid=871751869"