File:Ménages allocataires (Assistance sociale, Québec).svg

set terminal svg enhanced size 600,400
set output "AS.svg"
set encoding utf8
set multiplot
set size 1, 0.7
set origin 0, 0.3

set bmargin 0
set lmargin 11
set rmargin 2

set style line 100 lt 1 lc rgb "gray" lw 1
set style line 101 lt 0.5 lc rgb "gray" lw 1

#Formattage des données d'entrée
set xdata time
set timefmt "%Y-%m-%d"

#Formattage : Axe horizontal (x)
set xtics nomirror
set xrange ["1998-04-01":"2023-02-01"]
set xtics scale 0.001
set format x ""

#Formattage : Axe vertical (y)
set ytics scale 0
set yrange [190000:450000]
set ylabel "Ménages allocataires"

# Grille
set grid mytics ytics ls 100, ls 101
set grid mxtics xtics ls 100, ls 101
set grid mxtics
unset key

# Fonds colorés gvt.
set object 1 rect from first "1990-01-01", graph 0 to first "1994-09-12", graph 40 back
set object 1 rect fc rgb "#F08080" fillstyle solid 0.25 border lw 0

set object 2 rect from first "1994-09-12", graph 0 to first "2003-04-14", graph 40 back
set object 2 rect fc rgb "#004C9D" fillstyle solid 0.25 border lw 0

set object 3 rect from first "2003-04-14", graph 0 to first "2012-09-04", graph 40 back
set object 3 rect fc rgb "#F08080" fillstyle solid 0.25 border lw 0

set object 4 rect from first "2012-09-04", graph 0 to first "2014-04-07", graph 40 back
set object 4 rect fc rgb "#004C9D" fillstyle solid 0.25 border lw 0

set object 5 rect from first "2014-04-07", graph 0 to first "2018-10-01", graph 40 back
set object 5 rect fc rgb "#F08080" fillstyle solid 0.25 border lw 0

set object 6 rect from first "2018-10-01", graph 0 to first "2024-01-01", graph 40 back
set object 6 rect fc rgb "#1E90FF" fillstyle solid 0.25 border lw 0

plot "source.txt" using 1:2 with lines linewidth 2 linecolor rgb 'blue' title 'Ménages allocataires'

# Mise en place 2e graphique
f(x) = 0*x
set bmargin
set size 1.0, 0.3
set origin 0.0, 0.0
set tmargin 0

# Cadre titre
set object 7 rect from first "1998-01-01", first 15  to first "2024-09-12", first 23 back
set object 7 rect fc rgb "#606060" fillstyle solid 1 border lw 0
set label "ÉVOLUTION EN GLISSEMENT ANNUEL" at "1998-10-01",18.5 tc rgb "white" font "Arial,9"
set style fill transparent solid 0.5 noborder

#Formattage : Axe horizontal (x)
set format x "%Y"

#Formattage : Axe vertical (y)
set yrange [-18:23]
set ytics -20,10,10
set ytics scale 0.01
set mytics 2
set ylabel ""
set format y "%'.0f %%"

plot "sourceVar.txt" using 1:2 with filledcurves below y1=0 fillcolor rgb "green",\
"" using 1:2 with filledcurves above y1=0 fillcolor rgb "red",\
"" using 1:2 with lines linewidth 1 linecolor rgb 'black' title 'Ménages allocataires'