File:Magnetic-force-on-particle.png

From Wikimedia Commons, the free media repository
Jump to navigation Jump to search

Original file ‎(1,042 × 1,043 pixels, file size: 117 KB, MIME type: image/png)

Captions

Captions

Add a one-line explanation of what this file represents

Summary

[edit]
Description
English: Magnetic force on a charged particle for different angles. green: direction of the mangnetic field, blue: velocity, red: force on the particle
Date
Source Own work
Author MikeRun
PNG development
InfoField
 
This PNG graphic was created with POV-Ray.

POV-Ray code

POV-Ray source code 
#include "colors.inc"
#include "textures.inc"

background {White}

#declare fieldlinecolor=<0,1,0,0.9>;
#declare vvectorcolor=<0,0,1>;
#declare forcevectorcolor=<1,0,0>;

#declare smallwidth=0.05;
#declare normalwidth=0.1;
#declare largewidth=0.15;

#declare BVecLength=6;
#declare VVecLength=2;

#declare kr=0.2;

#macro MakeFieldVec (mylength,mywidth,veccolor)
  merge {
    cylinder { 
        <0, 0, 0>, <0, 0, mylength>, mywidth pigment 
        { color veccolor }
    }
    cone { 
        <0, 0, mylength>, mywidth+0.1, <0, 0, mylength+1>, 0 pigment 
        { color veccolor }
    }
  }
#end

#macro MakeParticle (particleLocation)
  sphere {
    particleLocation, kr
    pigment {color Black}
  }
#end

#declare torusMajor=1.5;
#declare torusMinor=0.05;
#macro MakeAngleIndicator (Pos, Angle)
    object {
            difference {
                    torus {
                      torusMajor, torusMinor
                      rotate z*-90
                    }
                union {
                    object {
                     box { <-2*torusMajor, -2*torusMajor, -2*torusMajor>, <2*torusMajor, 2*torusMajor, 0> }
                     rotate x*(-90)
                    }
                    object {
                     box { <-2*torusMajor, -2*torusMajor, -2*torusMajor>, <2*torusMajor, 2*torusMajor, 0> }
                     rotate x*(+90-Angle)
                    }
                }
            }
            pigment { Black }
        translate Pos
    }
#end


// create background plane

box {
  <0, 0, 0>, <10,16,0.001>
  pigment {color <1,1,1,0.9>}
  translate <-2, -2, 0>
} 


// create magnetic field vectors

#for (XCount,0,2)
  #for (YCount,0,3)
    object {
        MakeFieldVec (BVecLength,smallwidth,fieldlinecolor) 
        translate <3*XCount, 4*YCount, 0>
    }
  #end
#end



// particle 1: velocity vector and force vector (velocity 0° to magnetic field)

#declare Pos=<6, 12, 0>;
object {
   MakeFieldVec (VVecLength,normalwidth,vvectorcolor)
   rotate <0, 0, 0>
   translate Pos
}
MakeParticle (Pos)



// particle 2: velocity vector and force vector (velocity 30° to magnetic field)


#declare Pos=<6, 8, 0>;
#declare Angle=30;
object {
   MakeFieldVec (VVecLength,normalwidth,vvectorcolor)
   rotate <-1*Angle, 0, 0>
   translate Pos
}
object {
   MakeFieldVec (3*sin(radians(Angle))*VVecLength,normalwidth,forcevectorcolor)
   rotate <0, -90, 0>
   translate Pos
}
MakeParticle (Pos)
MakeAngleIndicator (Pos,Angle)



// particle 3: velocity vector and force vector (velocity 60° to magnetic field)


#declare Pos=<6, 4, 0>;
#declare Angle=60;
object {
   MakeFieldVec (VVecLength,normalwidth,vvectorcolor)
   rotate <-1*Angle, 0, 0>
   translate Pos
}
object {
   MakeFieldVec (3*sin(radians(Angle))*VVecLength,normalwidth,forcevectorcolor)
   rotate <0, -90, 0>
   translate Pos
}
MakeParticle (Pos)
MakeAngleIndicator (Pos,Angle)
                   


// particle 4: velocity vector and force vector (velocity 90° to magnetic field)

#declare Pos=<6, 0, 0>;
#declare Angle=90;
object {
   MakeFieldVec (VVecLength,normalwidth,vvectorcolor)
   rotate <-1*Angle, 0, 0>
   translate Pos
}
object {
   MakeFieldVec (3*VVecLength,normalwidth,forcevectorcolor)
   rotate <0, -90, 0>
   translate Pos
}
MakeParticle (Pos)
MakeAngleIndicator (Pos,Angle)


// camera & lights

#declare campos=<17, 14, 14>;
camera {
    location campos
    look_at <3, 6, 0>
}

light_source {
  campos 
  color White 
}

 
This image was created with POV-Ray.

Licensing

[edit]
I, the copyright holder of this work, hereby publish it under the following license:
w:en:Creative Commons
attribution share alike
This file is licensed under the Creative Commons Attribution-Share Alike 4.0 International license.
You are free:
  • to share – to copy, distribute and transmit the work
  • to remix – to adapt the work
Under the following conditions:
  • attribution – You must give appropriate credit, provide a link to the license, and indicate if changes were made. You may do so in any reasonable manner, but not in any way that suggests the licensor endorses you or your use.
  • share alike – If you remix, transform, or build upon the material, you must distribute your contributions under the same or compatible license as the original.

File history

Click on a date/time to view the file as it appeared at that time.

Date/TimeThumbnailDimensionsUserComment
current10:21, 14 May 2020Thumbnail for version as of 10:21, 14 May 20201,042 × 1,043 (117 KB)MikeRun (talk | contribs)Uploaded own work with UploadWizard

You cannot overwrite this file.

The following page uses this file:

Metadata

This file contains additional information such as Exif metadata which may have been added by the digital camera, scanner, or software program used to create or digitize it. If the file has been modified from its original state, some details such as the timestamp may not fully reflect those of the original file. The timestamp is only as accurate as the clock in the camera, and it may be completely wrong.

Retrieved from "https://commons.wikimedia.org/w/index.php?title=File:Magnetic-force-on-particle.png&oldid=487314219"