File:Plenoptic function b.svg

prologues := 3;
beginfig(1);

pair orig; orig = (5cm,5cm);
axisposlen = 3cm; axisneglen = 1cm;
z1 = orig - (axisneglen,0);       % left end of x axis
vectorang = 65;
z2 = orig - 1cm * dir vectorang;  % start of vector line
z3 = orig + 3cm * dir vectorang;  % end of vector line

% axes
pair axisend[];
axisend1 = orig + (axisposlen,0);
draw z1--axisend1;
label.rt(btex $x$ etex, axisend1);
axisend2 = orig + (0,axisposlen);
draw (orig - (0,axisneglen))--axisend2;
label.top(btex $y$ etex, axisend2);
axisend3 = orig + axisposlen * dir 45;
draw (orig - axisneglen * dir 45)--axisend3;
label.rt(btex $z$ etex, axisend3);
pickup pencircle scaled 4pt;
drawdot(orig);

% dotted line for phi angle
z4 = 0.8[orig,z3];
z5 = (x4, ypart orig + 0.5cm);
linecap := butt;
pickup defaultpen;
draw z4--z5--orig dashed evenly;

% theta and phi labels and their curves
angdist = 0.8cm;
z6 = orig + angdist * up;
draw z6{right}..(orig + angdist * dir vectorang);
label.lft(btex $\theta$ etex, z6);
z7 = orig + angdist * right;
draw z7{up}..(orig + angdist * unitvector(z5 - orig));
label.bot(btex $\phi$ etex, z7);

% vector
pickup pencircle scaled 1pt;
linecap := rounded;
drawarrow z2--z3;
label.ulft(btex $(x,y,z)$ etex, orig);
label.rt(btex $L(x,y,z,\theta,\phi)$ etex, z3);

endfig;
end