File:TLSRWA.gif

(* Source code written in Mathematica 11.1 by Rolancito, Feb. 2018. This source code is public domain. *)
(* Time evolution of a two-level-system with level splitting = 1 interacting with a laser beam on resonance and coupling term = 0.1 *)
ClearAll["Global`*"]
(* Coupled differential equations *)
CDE = NDSolve[{I cg'[t] == ce[t] 0.1 Cos[-t] E^(-I t), I ce'[t] == cg[t] 0.1 Cos[-t] E^(I t), cg[0] == 0, ce[0] == 1}, {cg, ce}, {t, 0, 20 \[Pi]}]
CDERWA = NDSolve[{I cg'[t] == ce[t] 0.1 /2, I ce'[t] == cg[t] 0.1 /2, cg[0] == 0, ce[0] == 1}, {cg, ce}, {t, 0, 20 \[Pi]}]
(* Bloch sphere *)
tlsrwagif = 
  Table[Show[
    ParametricPlot3D[
     Evaluate[{2 Re[cg[t] Conjugate[ce[t]]], 
          2 Im[ce[t] Conjugate[cg[t]]], 
          cg[t] Conjugate[cg[t]] - 
           ce[t] Conjugate[ce[t]]} /. # & /@ {CDE, CDERWA}], {t, 0, 
      20 \[Pi]}, PlotRange -> All, 
     ColorFunction -> Function[{t}, Hue[t]]], 
    Graphics3D[{PointSize[Large], 
      Point[Evaluate[{2 Re[cg[time] Conjugate[ce[time]]], 
          2 Im[ce[time] Conjugate[cg[time]]], 
          cg[time] Conjugate[cg[time]] - 
           ce[time] Conjugate[ce[time]]} /. CDE]], Opacity[0.5], 
      Sphere[{0, 0, 0}, 1]}]], {time, 0, 20 \[Pi], \[Pi]/5}];
Export["TLSRWA.gif", tlsrwagif, "AnimationRepetitions" -> \[Infinity]]

I, the copyright holder of this work, hereby publish it under the following license:

This file is licensed under the Creative Commons Attribution-Share Alike 4.0 International license.

You are free:

• to share – to copy, distribute and transmit the work
• to remix – to adapt the work

Under the following conditions:

• attribution – You must give appropriate credit, provide a link to the license, and indicate if changes were made. You may do so in any reasonable manner, but not in any way that suggests the licensor endorses you or your use.
• share alike – If you remix, transform, or build upon the material, you must distribute your contributions under the same or compatible license as the original.

https://creativecommons.org/licenses/by-sa/4.0CC BY-SA 4.0 Creative Commons Attribution-Share Alike 4.0 truetrue