File:Temperature anomalies 2010-06.svg

 

This W3C-unspecified plot was created with Gnuplot.

# Temp data is last data set from
# ftp://ftp.ncdc.noaa.gov/pub/data/ghcn/blended/ncdc_blended_merg53v3b.dat.gz
# Each grid point covers 5 deg of lat and lon
#
# Map data is generated from 
#
#	nugsl-worldmap -m 0 -e 0 -o /tmp/map2.svg
#
# And then post processed:
# perl -e 'undef $/; $_=<>; s/".*?d="/\n\n/msg; s/ C /\nC /msg; s/,/ /msg; print' < map2.svg > map2.txt
#
# Map data goes up to 2752.766 and 1537.631, so 7.6465 and 8.5423 pixel/deg
latscale=1537.631/180
lonscale=2752.766/360


set term svg size 2048,1536 fsize 40
set output "Temperature anomalies 2010-06.svg"
set pm3d map 
set palette defined (-2 "blue", 0 "white", 5 "red")
set border 0
# screen relative borders are gnuplot 4.4 only
set bmargin at screen 0
set lmargin at screen 0
set rmargin at screen 0.9
set tmargin at screen 0.9
set noxtics
set noytics
set noztics
set nokey
set noclabel

set title "Temperature Anomalies 2010-06\n(Degrees Celsius relative to 1961-1990)"

splot [-185:180] [-90:90] [-5:6] \
	"temp.dat" \
		matrix \
		using (-180+$1*5):(90-$2*5):($3/100) \
		notitle, \
	"/tmp/map2.txt" \
		using (-180+$2/lonscale):(90-$3/latscale):(-5) \
		lt -1 \
		lw 0.5 \
		notitle \
		with lines \

I, the copyright holder of this work, hereby publish it under the following licenses:

This file is licensed under the Creative Commons Attribution-Share Alike 3.0 Unported license.

You are free:

• to share – to copy, distribute and transmit the work
• to remix – to adapt the work

Under the following conditions:

• attribution – You must give appropriate credit, provide a link to the license, and indicate if changes were made. You may do so in any reasonable manner, but not in any way that suggests the licensor endorses you or your use.
• share alike – If you remix, transform, or build upon the material, you must distribute your contributions under the same or compatible license as the original.

https://creativecommons.org/licenses/by-sa/3.0CC BY-SA 3.0 Creative Commons Attribution-Share Alike 3.0 truetrue

Permission is granted to copy, distribute and/or modify this document under the terms of the GNU Free Documentation License, Version 1.2 or any later version published by the Free Software Foundation; with no Invariant Sections, no Front-Cover Texts, and no Back-Cover Texts. A copy of the license is included in the section entitled GNU Free Documentation License.http://www.gnu.org/copyleft/fdl.htmlGFDLGNU Free Documentation Licensetruetrue

You may select the license of your choice.