File talk:Helix diagram.png

POV-Ray scene file

//helix.png for POV-Ray v3.6 by Y. tambe 
//You can use this source file as public-domain
camera {
	angle 5
	location <0.0, 0.0, 90>
	look_at <0.0, 0.0, 0.0>
	translate 0.3*y
}
light_source {
	<0, 500, 1000>
	rgb <1, 1, 1>
	shadowless
}

#declare pole=
union{//pole
cylinder{ 2*y, -2*y, 0.5
	texture{
		pigment{
		planar//patially transparent
		pigment_map{
		[ 0 color rgbt<1,1,1,0> ]
		[ 0.5 color rgbt<1,1,1,0.5> ]
		[ 1 color rgbt<1,1,1,0.2> ]
		}
		}
		finish{ ambient 0.05 diffuse 1}
	scale 2*y
	}
}
}

#declare step=5;

//S (left-handed, though placed on right)
union{
#declare c1=0-90;
merge{
#while (c1<360*1.5+90)
	cylinder{
		vaxis_rotate(<0.535,0,0>,y, c1)-1.2*y+(1.2*2)/1.5/360*c1*y,
		vaxis_rotate(<0.535,0,0>,y, (c1+step))-1.2*y+(1.2*2)/1.5/360*(c1+step)*y,
		0.035
	}
#declare c1=c1+step;
#end
		texture{
			pigment{
			planar
			pigment_map{
			[ 0 color rgbt<0.5,1,0.5,1> ]
			[ 0.1 color rgbt<0.5,1,0.5,0> ]
			[ 1 color rgbt<0.5,1,0.5,0> ]
			}
			}
			finish{ ambient 0.4 diffuse 0.6}
			scale 1.5*y
		}
}
object{pole}

rotate 10*x
translate -1.4*x
}

//Z (right-handed, though placed on left)
union{
#declare c1=0-90;
merge{
#while (c1<360*1.5+90)
	cylinder{
		vaxis_rotate(<-0.535,0,0>,y, -c1)-1.2*y+(1.2*2)/1.5/360*c1*y,
		vaxis_rotate(<-0.535,0,0>,y, -(c1+step))-1.2*y+(1.2*2)/1.5/360*(c1+step)*y,
		0.035
	}
#declare c1=c1+step;
#end
		texture{
			pigment{
			planar
			pigment_map{
			[ 0 color rgbt<0.5,1,0.5,1> ]
			[ 0.1 color rgbt<0.5,1,0.5,0> ]
			[ 1 color rgbt<0.5,1,0.5,0> ]
			}
			}
			finish{ ambient 0.4 diffuse 0.6}
			scale 1.5*y
		}
}
object{pole}

rotate 10*x
translate 1.4*x
}

//anotations
text{
ttf "cyrvetic.ttf",
"A", 
0.5,0
rotate 180*y
scale 0.6
translate <2.4, 2.2,0>
}
text{
ttf "cyrvetic.ttf",
"B", 
0.5,0
rotate 180*y
scale 0.6
translate <-.5, 2.2,0>
}