File:Drawtangram preview.gif

; Created in LibreOffice 4.2 with this LibreLogo program
 ; Usage: Put this code into an English language document in LibO Writer,
 ; and click on the Start icon of the View»Toolbars»Logo toolbar.
 TO place x y
 POSITION [200+x*40, 400-y*40]
 END
 
 TO line x y x2 y2
 PENUP place x y
 PENDOWN place x2 y2
 END
 
 TO grid x y x2 y2
 REPEAT y2-y+1 [ line x y+REPCOUNT-1 x2 y+REPCOUNT-1 ]
 REPEAT x2-x+1 [ line x+REPCOUNT-1 y x+REPCOUNT-1 y2 ]
 END
 
 TO steps n
 PENSIZE 2 HIDETURTLE
 PENCAP “ROUND”
 PENCOLOR “SILVER”
 IF n < 6 [
 grid 0 0 4 4
 IF n = 0 [ STOP ]
 ]
 PENCOLOR “BLACK”
 IF n < 6 [
 line 0 4 4 0
 IF n = 1 [ STOP ]
 line 2 4 4 2
 IF n = 2 [ STOP ]
 line 1 3 2 4
 IF n = 3 [ STOP ]
 line 0 0 3 3
 IF n = 4 [ STOP ]
 line 3 3 3 1 
 IF n = 5 [ STOP ]
 ]
 FILLCOLOR “RED” line 0 0 0 4 place 2 2 FILL
 FILLCOLOR “BLUE” line 0 0 4 0 place 2 2 FILL
 FILLCOLOR “GREEN” line 0 4 2 4 place 1 3 FILL
 FILLCOLOR “PURPLE” line 2 4 4 4 place 4 2 FILL
 FILLCOLOR “LIME” line 3 1 2 2 place 3 3 FILL
 FILLCOLOR “FUCHSIA” line 2 4 1 3 place 2 2 place 3 3 FILL
 FILLCOLOR “YELLOW” line 3 1 3 3 place 4 2 place 4 0 FILL
 END
 
 REPEAT 7 [
     PICTURE “tangram_step%s.svg” % REPCOUNT [
         steps REPCOUNT - 1
     ]
 ]